久久久久久久999_99精品久久精品一区二区爱城_成人欧美一区二区三区在线播放_国产精品日本一区二区不卡视频_国产午夜视频_欧美精品在线观看免费

標題: Proteus設計的51單片機匯編語言電子密碼鎖 [打印本頁]
作者: hurui88866    時間: 2017-12-14 13:40
標題: Proteus設計的51單片機匯編語言電子密碼鎖
密碼鎖仿真圖，源程序代碼。
仿真原理圖如下（proteus仿真工程文件可到本帖附件中下載）


單片機匯編語言源程序如下:
  1. ;===================================================
  2. ;名    稱:電子密碼鎖
  3. ;作    者:小發
  4. ;日    期:2007年06月13日
  5. ;修改日期:2007年06月18日
  6. ;說    明:首先顯示器提示輸入密碼,密碼在12.5S內輸入有效,
  7. ;         輸入次三次錯誤報警10S,輸入正確開門,7秒后返回初態
  8. ;         以上參數均可在主程序里設定,修改系統密碼在程序的結尾
  9. ;===================================================

  11.         RS BIT P2.7
  12.         RW BIT P2.6
  13.         E BIT P2.5
  14.         ENTER BIT 22H.0
  15.         OPEN BIT P3.6
  16.         SPEAK BIT P3.7
  17.         PASSBUF EQU 40H
  18.         KEYNUMBER EQU 41H       ;存放識別后的按鍵號
  19.         ORG 0000H
  20.         AJMP MAIN
  21.         ORG 0003H
  22.         JMP KEY_INT
  23.         ORG 000BH
  24.         AJMP INTT0
  25.         ORG 001BH
  26.         AJMP INTT1
  27.         ORG 0030H
  28. ;========== 主程序開始 ==============
  29. MAIN:   MOV 30H,#07H          ;輸入密碼為7位  最高只可設15位
  30.         MOV 42H,#200         ;設定報警的時間,42H單元里的數*50MS
  31.         MOV 43H,#250          ;設定開門時間     14的倍數(實際上液晶顯示器執行指令占用了時間,開門時間會比14*250MS大)
  32.         ;44H號單元存放輸入錯誤的次數
  33.         ;45H為定時器0中斷次數
  34.         ;46H為定時器1中斷次數
  35.         MOV 47H,#250          ;輸入密碼時間設定,50MS倍數
  36.         MOV SP,#60H
  37.         CLR OPEN
  38.         CLR SPEAK              ;初始化輸出設備
  39.         CLR ENTER              ;標志位初始化
  40.        
  41.         MOV TMOD,#11H          ;定時器工作方式2
  42.         MOV TH0,#3CH           ;初值50MS
  43.         MOV TL0,#0BH
  44.         MOV TH1,#3CH           
  45.         MOV TL1,#0BH
  46.         SETB EA
  47.         SETB ET0
  48.         SETB ET1
  49.         
  50.         MOV TCON,#00000000B     ;電平觸發
  51. START:  MOV R0,30H
  52.         MOV R1,#31H
  53. SS1:        MOV @R1,#00H
  54.         INC R1
  55.         DJNZ R0,SS1            ;將輸入密碼緩沖單元清零
  56.         MOV P1,#0FH            ;初始化按鍵口
  57.         MOV R1,#31H             ;從31號單元開始存放按建輸入的密碼         
  58.         CLR 20H                 ;報警標志清零
  59.         CLR 21H                 ;密碼超時標志
  60.         MOV 46H,#00H           ;超時后對定時器中斷次數清零,便于下一輪重新計時
  61. INIT:   ACALL SELLCD            ;設定液晶工作方式
  62.         ACALL LINE1             ;在第一行顯示
  63.         MOV DPTR,#MES_P         ;顯示請輸入密碼
  64.         ACALL DISPLAY
  65.         setb EX0               ;開中斷,允許鍵盤輸入
  66. KEYIN:  JB  21H,ERR             ;超時轉到錯誤程序
  67.         JNB ENTER,KEYIN         ;等待ENTER按下
  68.         CLR ENTER
  69.         clr EX0                ;密碼輸入完后鎖定鍵盤
  70. ;當使用邊沿觸發時用上面的指令為什么禁止不了中斷???
  71. ;========== 密碼判斷程序 ============
  72. COMP:            
  73.         MOV DPTR,#PASS
  74.         MOV R4,30H             ;密碼的長度
  75.         MOV A,#0
  76.         MOV R1,#31H            
  77. LOOP:   MOV R5,A
  78.         MOVC A,@A+DPTR
  79.         MOV PASSBUF,A          ;取出系統設定的密碼
  80.         MOV A,@R1              ;從31號單元開始取出輸入的密碼
  81.         CJNE A,PASSBUF,ERR     ;比較
  82.         MOV A,R5
  83.         INC A
  84.         INC R1                 ;取下一位
  85.         DJNZ R4,LOOP

  87. ;正確
  88. MATCH:  MOV A,#01H
  89.         ACALL ENABLE           ;清屏,光標復位
  90.         ACALL LINE1            ;從第一行開始顯示
  91.         MOV DPTR,#MES_C
  92.         ACALL DISPLAY          ;顯示"請進"
  93.         ACALL LINE2
  94.         MOV DPTR,#TAB_1
  95.         ACALL DISPLAY
  96.         SETB OPEN              ;開門
  97.         MOV 44H,#00H           ;輸入錯誤次數清零
  98.         MOV R6,43H               
  99.         ACALL DELAY
  100.         CLR OPEN               ;復位
  101.         JMP START            
  102. ;錯誤
  103. ERR:    ACALL BACK
  104.         MOV R6,#03H
  105.         ACALL DELAY
  106.         ACALL BACK           ;輸錯提示音,鳴兩下
  107.         MOV A,#01H
  108.         ACALL ENABLE
  109.         ACALL LINE1
  110.         MOV DPTR,#MES_E
  111.         ACALL DISPLAY       ;顯示錯誤
  112.         MOV R6,#40H
  113.         ACALL DELAY         
  114.         INC  44H
  115.         MOV A,44H
  116.         CJNE A,#03H,EE0
  117. EE0:    JC  ERROUT        ;輸錯不到三次返回
  118.         MOV 44H,#00H        ;清零
  119.         ACALL WRANING       ;報警
  120. ERROUT: JMP START

  122. ;=========== 按鍵中斷服務程序 ==========
  123. KEY_INT:push acc
  124.         push psw
  125.         clr ex0
  126.         acall delay10ms     ;延時消抖
  127.         SETB TR1            ;啟動定時器
  128.         ACALL SMKEY         ;按鍵識別
  129.         MOV A,KEYNUMBER     ;返回按鍵號
  130.         ACALL BACK          ;按鍵發聲
  131.         MOV R3,A
  132.         CJNE R3,#0BH,K1     ;ENTER是否按下
  133.         SETB ENTER
  134.         clr tr1             ;按下確認后關畢定時器
  135.         mov 46h,#00h        ;對中斷次數清零
  136.         AJMP KEY_RTN
  137. K1:     ADD A,#30H          ;將按鍵號轉換為ASCⅡ碼
  138.         MOV @R1,A           ;將輸入的密碼存入緩沖單元
  139.         INC R1              ;修改地址
  140.         
  141.         ACALL WRDATA        ;輸入一位顯示一個"*"
  142.         
  143. KEY_RTN:pop psw
  144.         pop acc
  145.         setb ex0
  146.         RETI


  149. ;=========== 按鍵識別程序 ==========
  150. SMKEY:   
  151.          MOV A,P1
  152.          ANL A,#0FH
  153. WKEY:    MOV B,A               ;反轉法查詢  
  154.          MOV P1,#0F0H
  155.          NOP
  156.          MOV A,P1
  157.          ANL A,#0F0H
  158.          ORL A,B
  159.          MOV P1,#0FH         ;還原P1口初態
  160.          CJNE A,#0EEH,WKEY1
  161.          MOV KEYNUMBER,#00H      
  162.          AJMP RETURN
  163. WKEY1:   CJNE A,#0EDH,WKEY2
  164.          MOV KEYNUMBER,#01H
  165.          AJMP RETURN
  166. WKEY2:   CJNE A,#0EBH,WKEY3
  167.          MOV KEYNUMBER,#02H
  168.          AJMP RETURN
  169. WKEY3:   CJNE A,#0E7H,WKEY4
  170.          MOV KEYNUMBER,#03H
  171.          AJMP RETURN
  172. WKEY4:   CJNE A,#0DEH,WKEY5
  173.          MOV KEYNUMBER,#04H
  174.          AJMP RETURN
  175. WKEY5:   CJNE A,#0DDH,WKEY6
  176.          MOV KEYNUMBER,#05H
  177.          AJMP RETURN
  178. WKEY6:   CJNE A,#0DBH,WKEY7
  179.          MOV KEYNUMBER,#06H
  180.          AJMP RETURN
  181. WKEY7:   CJNE A,#0D7H,WKEY8
  182.          MOV KEYNUMBER,#07H
  183.          AJMP RETURN
  184. WKEY8:   CJNE A,#0BEH,WKEY9
  185.          MOV KEYNUMBER,#08H
  186.          AJMP RETURN
  187. WKEY9:   CJNE A,#0BdH,WKEY10
  188.          MOV KEYNUMBER,#09H
  189.          AJMP RETURN
  190. WKEY10:  CJNE A,#0BbH,WKEY11
  191.          MOV KEYNUMBER,#0AH
  192.          AJMP RETURN
  193. WKEY11:  CJNE A,#0B7H,RETURN
  194.          MOV KEYNUMBER,#0BH       ;判斷哪個鍵按下,返回相應按鍵號碼
  195. RETURN:  MOV P1,#0FH
  196.          NOP
  197.          NOP
  198.          MOV A,P1
  199.          CPL A
  200.          ANL A,#0FH
  201.          JNZ RETURN              ;等待按鍵松開
  202.          RET



  206. ;========== 液晶工作方式設置 ============
  207. SELLCD: MOV A,#01H          ;清屏,光標復位   
  208.         ACALL ENABLE
  209.         MOV A,#38H          ;設置顯示模式,8位兩行,5*7點陣
  210.         ACALL ENABLE
  211.         MOV A,#0DH          ;顯示器開,允許內爍
  212.         ACALL ENABLE      
  213.         MOV A,#06H          ;文字不動,光標右移
  214.         ACALL ENABLE
  215.         RET

  217. ;========== 液晶執行指令 ============
  218. ENABLE: CLR RS
  219.         CLR RW              ;RS,RW同為低電平時寫入指令
  220.         MOV P0,A
  221.         CLR E               ;E由高變低時執行指令
  222.         ACALL WAIT
  223.         SETB E
  224.         RET

  226. ;========== WAIT ============
  227. ;判斷液晶是否忙的子程序
  228. WAIT:   MOV P0,#0FFH
  229.         CLR RS
  230.         SETB RW             ;RW為高,RS為低時可讀忙信號
  231.         CLR E
  232.         NOP
  233.         SETB E
  234.         JB P0.7,WAIT
  235.         RET


  238.         
  239. ;========== 顯示的起始地址 ============
  240. ;在第一行
  241. LINE1:  MOV A,#80H
  242.         ACALL ENABLE
  243.         RET
  244. ;在第二行
  245. LINE2:  MOV A,#0C0H
  246.         ACALL ENABLE
  247.         RET


  250. ;=========== 顯示程序 ============
  251. DISPLAY:MOV R7,#00H
  252. NEXT:   MOV A,R7
  253.         MOVC A,@A+DPTR
  254.         CJNE A,#10H,DSP
  255.         RET
  256. DSP:    ACALL WRDATA
  257.         INC R7
  258.         AJMP NEXT

  260. ;========== 將A里面的數據寫入液晶 ============
  261. WRDATA: SETB RS
  262.         CLR RW
  263.         MOV P0,A
  264.         CLR E
  265.         ACALL WAIT
  266.         SETB E
  267.         RET

  269. ;=========== 報警程序 ============
  270. WRANING: SETB TR0
  271.          ACALL BACK
  272.          MOV R4,#00H
  273.          ACALL D2
  274.          JNB 20H, WRANING
  275.          RET
  276. ;=========== 發聲程序 ============
  277. BACK:    MOV R0,#100
  278. KK1:     CPL  SPEAK
  279.          LCALL DELAY2MS
  280.          DJNZ  R0,KK1             ;不斷取反P2.0使其產生一定頻率的方波推動揚聲器
  281.          RET                      ;延時的長短可以改變輸出的頻率

  283. ;=========== INTT0 ============
  284. ;報警時間設定
  285. INTT0:   PUSH ACC
  286.          PUSH PSW                  
  287.          MOV TH0,#3CH           
  288.          MOV TL0,#0BH
  289.          INC 45H
  290.          MOV A,45H
  291.          CJNE A,42H,INTT0OUT
  292.          MOV 45H,#00H
  293.          SETB 20H                 ;置標志位
  294.          CLR TR0                  ;關閉定時器
  295. INTT0OUT:POP PSW
  296.          POP ACC
  297.          RETI
  298. ;=========== INTT1 ============
  299. ;輸入超時
  300. INTT1:   PUSH ACC
  301.          PUSH PSW
  302.          INC 46H
  303.          MOV A,46H
  304.          CJNE A,47H,INTT1OUT
  305.          CLR TR1                 ;關閉定時器
  306.          SETB 21H                ;時間到置標志位       
  307.          MOV 47H,#00H            ;中斷次數清零
  308. INTT1OUT:POP PSW
  309.          POP ACC
  310.          RETI  
  311. ;=========== 延時程序 ============
  312. DELAY:    MOV R4,#38H
  313. D1:       MOV R5,#0F9H
  314.           DJNZ R5,$
  315.           DJNZ R4,D1
  316.           DJNZ R6,DELAY        ;14R6毫秒
  317.           RET
  318. DELAY2MS: MOV R4,#02H
  319. D2:       MOV R5,#0F0H
  320.           DJNZ R5,$
  321.           DJNZ R4,D2
  322.           RET
  323. DELAY10ms:  MOV R4,#20
  324. D3:         MOV R5,#248
  325.             DJNZ R5,$
  326.             DJNZ R4,D3
  327.             RET

  329. PASS:   DB "1314520"
  330. MES_P:  DB "Password?",10H
  331. MES_C:  DB "   welcome!",10H
  332. MES_E:  DB "Error!",10H
  333. TAB_1:  DB "xiao_fa office",10h     

  335.         END


復制代碼

所有資料51hei提供下載:
Proteus設計的51單片機電子密碼鎖.rar (44.96 KB, 下載次數: 120)


作者: hurui88866    時間: 2017-12-14 13:41
頂一下
作者: bottlewww    時間: 2017-12-20 16:47
樓主，這個怎么解決

微信圖片_20171220164709.png (5.95 KB, 下載次數: 96)

微信圖片_20171220164709.png
作者: 879598301    時間: 2018-1-11 21:28
頂一下
作者: yun6    時間: 2020-6-18 20:53
bottlewww 發表于 2017-12-20 16:47
**** 作者被禁止或刪除 內容自動屏蔽 ****

這個問題你解決了嗎？




歡迎光臨 (http://www.zg4o1577.cn/bbs/) Powered by Discuz! X3.1
主站蜘蛛池模板： 久久大| 毛片一级电影 | 黄色日本视频 | 99re国产精品 | 欧美亚洲在线视频 | 亚洲电影一区 | 一级黄色片美国 | 三级成人在线 | 免费在线观看av片 | 欧美日韩高清一区 | 日韩免费一区 | 久久精品久久久久久 | 古典武侠第一页久久777 | 一区二区三区网站 | 99免费在线视频 | 久久亚洲一区二区 | 天天视频成人 | 日日干夜夜操天天操 | 天天成人综合网 | 91麻豆精品国产91久久久更新资源速度超快 | 精品久久久久久久人人人人传媒 | 久久久精品久 | 91视频中文 | 日韩av成人在线 | 久久精品成人 | 欧美日韩精品一区二区天天拍 | 欧美精品久久久 | 国产一区二区三区免费观看在线 | 欧美黄色一区 | 欧美精品一区在线 | 国产精品久久久久久久久久久久久 | 欧美黑人一级爽快片淫片高清 | 亚洲激情在线观看 | 成人a免费 | 99久久精品免费看国产小宝寻花 | 自拍偷拍亚洲欧美 | 成人免费小视频 | 九九热在线精品视频 | 天堂亚洲| 久久久精彩视频 | 欧美a级成人淫片免费看 |