成人在线观看一区,不卡一区,成年人网站在线免费看

;========================================================================
;紅外遙控電容調(diào)速風扇控制器
;STC8G1K08(DIP16或SOP16)+TM1637顯示模塊+EC11編碼器+CBB電容
;楊小強，2022年8月
;內(nèi)部R/C時鐘，頻率選擇：11.0592MHz
;顯示：(TM1637)4位數(shù)碼管顯示模塊
;調(diào)整定時、檔位：EC11帶按鍵5腳旋轉(zhuǎn)編碼器。也可以用3只按鍵代替EC11編碼器
;
;工作時先全功率驅(qū)動繼電器，延時一定時間后轉(zhuǎn)為PWM方式驅(qū)動，以降低功耗減少發(fā)熱量，
;PWM周期25微秒*2=50微秒，頻率20KHz占空比50%，繼電器線圈并聯(lián)一只104電容，驅(qū)動電流降低到50%左右
;保持吸合狀態(tài)。
;如果使用可控硅控制就取消主程序中初始化部分的“SETB PWM”指令，或改為“CLR PWM”（禁止PWM驅(qū)動）
;
;EC11編碼器按鍵、旋轉(zhuǎn)動作：
; 1.旋轉(zhuǎn)編碼器：對當前顯示的“定時時間”或“檔位”作增(減)調(diào)整
; 2.短按1次：正常風與自然風(睡眠風)切換。自然風狀態(tài)時LED指示燈亮，只顯示定時時間。
; 3.短按2次：設置自然風(睡眠風)漸慢/漸快變化的上下限檔位范圍、各檔位變化的間隔時間(秒)
; 4.長按10秒：顯示“----”，紅外遙控信號解碼，遙控器按鍵功能定義。定義好后須長按10秒才保存
;
;短按編碼器按鍵2次設置自然風(睡眠風)漸慢/漸快變化的上下限檔位范圍、檔位變化的間隔時間(秒)：
; 1.顯示：L-最低檔位下限，旋轉(zhuǎn)編碼器加/減，上、下限檔位之間最少間隔3檔。
; 2.顯示：H-最高檔位上限，旋轉(zhuǎn)編碼器加/減，上、下限檔位之間最少間隔3檔。
; 3.顯示：E-檔位漸慢/漸快變化時的間隔時間(1~5秒)，旋轉(zhuǎn)編碼器加/減
;設置好一項，短按編碼器按鍵或者閃爍5秒無操作，自動跳到下一項。
;短按2次編碼器按鍵保存并退出，或在第3項時無操作閃爍5秒自動保存并退出。
;
;長按10秒顯示“----”進入紅外遙控器的按鍵定義：
;定義1“關”、2“開/風速”、3“定時”、4“自然風”、5“+”、6“－”六個功能鍵。
; 交替顯示功能編號+遙控器客戶碼(不顯示反碼)和原來保存的按鍵值，按鍵值為數(shù)據(jù)碼+數(shù)據(jù)碼反碼
;共4個十六進制數(shù)，按下遙控器按鍵收到信號解碼成功并顯示，即為新的按鍵值，遙控器客戶碼與原來保
;存的不相同時，自動刪除舊的數(shù)據(jù)(保存才會生效)，短按跳到下一個功能編號，也可以旋轉(zhuǎn)EC11編碼器
;向前/后跳到任意編號，全部或部分定義好后，長按10秒編碼器按鍵顯示“----”保存并退出才生效，
;短按兩次退出或60秒無操作自動退出，不保存，仍然還是原來的數(shù)據(jù)。
;
;1“關”鍵：定時時間清零，關風扇
;2“開/風速”鍵：當定時時間為零時，置上電默認定時時間，開風扇；定時時間不為零時，檔位
; 加1，到最高檔后又從1檔開始循環(huán)，支持長按連續(xù)加；自然風(睡眠風)狀態(tài)時
; 不能調(diào)整檔位。
;3“定時”鍵：增加定時時間。風扇在關的狀態(tài)時，增加定時時間立即開風扇。
;4“自然風”鍵：正常風與自然風(睡眠風)切換，自然風(睡眠風)狀態(tài)時LED指示燈亮，只顯示定時時間。
;5“+”鍵：對當前顯示的“定時時間”或“檔位”作增加調(diào)整，支持長按連續(xù)加。
;6“-”鍵：對當前顯示的“定時時間”或“檔位”作減少調(diào)整，支持長按連續(xù)減。
;
;保存失敗顯示5秒E1
;
;P3口接6只繼電器（5只CBB電容，耐壓400V或630V)、LED指示燈、紅外接收頭：
;P3.0----9腳，繼電器，1uF
;P3.1----10腳，繼電器，2.2uF
;P3.2----11腳，繼電器，3.3uF
;P3.3----12腳，繼電器，4.7uF
;P3.4----13腳，繼電器，4.7uF
;P3.5----14腳，繼電器，直通
;P3.6----15腳，自然風LED指示燈，低電平亮
;P3.7----16腳，紅外接收頭
;
;各檔檔位控制碼及對應的電容容量：
;01檔：控制碼FEH，P3.0控制的繼電器導通，電容容量1uF
;02檔：控制碼FDH，P3.1控制的繼電器導通，電容容量2.2uF
;03檔：控制碼FBH，P3.2控制的繼電器導通，電容容量3.3uF
;04檔：控制碼FAH，P3.0、P3.2控制的繼電器導通，電容容量1uF+3.3uF=4.3uF
;05檔：控制碼F9H，P3.1、P3.2控制的繼電器導通，電容容量2.2uF+3.3uF=5.5uF
;06檔：控制碼F8H，P3.0、P3.1、P3.2控制的繼電器導通，電容容量1uF+2.2uF+3.3uF=6.5uF
;07檔：控制碼F4H，P3.0、P3.1、P3.3控制的繼電器導通，電容容量1uF+2.2uF+4.7uF=7.9uF
;08檔：控制碼F2H，P3.0、P3.2、P3.3控制的繼電器導通，電容容量1uF+3.3uF+4.7uF=9uF
;09檔：控制碼F1H，P3.1、P3.2、P3.3控制的繼電器導通，電容容量2.2uF+3.3uF+4.7uF=10.2uF
;10檔：控制碼F0H，P3.0、P3.1、P3.2、P3.3控制的繼電器導通，電容容量1uF+2.2uF+3.3uF+4.7uF=11.2uF
;11檔：控制碼E4H，P3.0、P3.1、P3.3、P3.4控制的繼電器導通，電容容量1uF+2.2uF+4.7uF+4.7uF=12.6uF
;12檔：控制碼E2H，P3.0、P3.2、P3.3、P3.4控制的繼電器導通，電容容量1uF+3.3uF+4.7uF+4.7uF=13.7uF
;13檔：控制碼E1H，P3.1、P3.2、P3.3、P3.4控制的繼電器導通，電容容量2.2uF+3.3uF+4.7uF+4.7uF=14.9uF
;14檔：控制碼E0H，P3.0、P3.1、P3.2、P3.3、P3.4控制的繼電器導通，電容容量1uF+2.2uF+3.3uF+4.7uF+4.7uF=15.9uF
;15檔：控制碼DFH，P3.5控制的繼電器導通，直通。
;
;----------------------------- 端口定義 ------------------------------------
P5 DATA 0C8H ;P5口定義
P1M1 DATA 091H ;P1口配置寄存器1
P1M0 DATA 092H ;P1口配置寄存器0
P3M1 DATA 0B1H ;P3口配置寄存器1
P3M0 DATA 0B2H ;P3口配置寄存器0
P5M1 DATA 0C9H ;P5口配置寄存器1
P5M0 DATA 0CAH ;P5口配置寄存器0
CLK EQU P1.0 ;1腳，接顯示模塊TM1637的CLK
DIO EQU P1.1 ;2腳，接顯示模塊TM1637的DIO
EC11A EQU P1.6 ;3腳，接編碼器的A引腳（+）
EC11B EQU P1.7 ;4腳，接編碼器的B引腳（-）
EC11K EQU P5.4 ;5腳，接編碼器的按鍵KEY
LED EQU P3.6 ;15腳，自然風狀態(tài)LED指示燈，低電平亮
IR EQU P3.7 ;16腳，紅外接收頭
BUZZER EQU P5.5 ;7腳，無源蜂鳴器
;---------------------------- 位地址及RAM的使用 ----------------------------
BMQDZ BIT 20H.0 ;編碼器動作，1=編碼器有旋轉(zhuǎn)動作；0=沒有旋轉(zhuǎn)動作
XZFX BIT 20H.1 ;旋轉(zhuǎn)方向，1=編碼器順時針正轉(zhuǎn)；0=編碼器逆時針反轉(zhuǎn)
FLQH BIT 20H.2 ;風類切換，1=自然風(睡眠風)；0=正常風
TSFX BIT 20H.3 ;調(diào)速方向，1=漸快；0=漸慢。自然風漸變控制時的調(diào)速方向。
YSBC BIT 20H.4 ;延時保存，1=在MJS倒計時結(jié)束時保存檔位。
SSBZ BIT 20H.5 ;閃爍標志，1=不顯示，0=顯示，數(shù)字及冒號閃爍時用，每0.5秒變化一次。
XSNRXZ BIT 20H.6 ;顯示內(nèi)容選擇，1=顯示檔位；0=顯示定時時間。
XSKG BIT 20H.7 ;顯示開關，1=關閉T1中斷的顯示功能，0=允許顯示定時和檔位等內(nèi)容
XSQHY BIT 21H.0 ;顯示切換1，1=顯示自然風檔位變化范圍或紅外解碼顯示；0=顯示檔位或定時。
XSQHE BIT 21H.1 ;顯示切換2，1=顯示自然風檔位變化范圍；0=紅外遙控信號解碼顯示。設置時用
BMXSQH BIT 21H.2 ;編碼顯示切換，1=顯示數(shù)據(jù)碼+反碼；0=顯示功能編號+系統(tǒng)碼。設置時用
PWM BIT 21H.3 ;1=使用PWM方式驅(qū)動；0=禁止PWM驅(qū)動
PWMBZ BIT 21H.4 ;PWM的電平狀態(tài)標志，1=高電平，0=低電平。PWM周期25微秒*2=50微秒，20KHz占空比50%
EEPBC BIT 21H.5 ;EEPROM操作子程序調(diào)用標志，1=EEPROM操作子程序正在調(diào)用繼電器控制程序
FWBZ0 EQU 022H ;閃爍顯示時長(秒)。受干擾等原因?qū)е聫臀粫r閃爍10秒
DSSJS EQU 023H ;定時時間，時
DSSJF EQU 024H ;定時時間，分
DSSJM EQU 025H ;定時時間，秒
SMGLD EQU 026H ;數(shù)碼管亮度，1~8級
DSDWJG EQU 027H ;上電設置的定時與檔位交替顯示的間隔時間(秒)
DSDW EQU 028H ;運行時使用，定時與檔位交替顯示的間隔時間(秒)
SMFJG2 EQU 029H ;運行時使用，自然風(睡眠風)檔位變化的間隔時間(秒)
DANGW EQU 02AH ;運行時使用，自然風(睡眠風)變化時的實時檔位
XMBH EQU 02BH ;項目編號，設置時使用
HM EQU 02CH ;毫秒，每毫秒減1，為0后重新放入計數(shù)值。定時器1使用，時間、顯示處理
SHMJS EQU 02DH ;(10)毫秒倒計時，每10毫秒減1，直到為0
HMJS EQU 02EH ;(10)毫秒計數(shù)，為0后重新放入99（1秒）
MJS EQU 02FH ;秒計數(shù)，每秒減1，直到為0，主程序使用
XSHC1 EQU 030H ;顯示緩存1，與上次不同就立即顯示，否則0.5秒顯示一次
XSHC2 EQU 031H ;顯示緩存2，與上次不同就立即顯示，否則0.5秒顯示一次
ZXM1 EQU 032H ;顯示用，待發(fā)送到TM1637的字形碼1
ZXM2 EQU 033H ;顯示用，待發(fā)送到TM1637的字形碼2
ZXM3 EQU 034H ;顯示用，待發(fā)送到TM1637的字形碼3
ZXM4 EQU 035H ;顯示用，待發(fā)送到TM1637的字形碼4
MA1 EQU 036H ;接收到的紅外遙控系統(tǒng)碼(客戶碼)
MA2 EQU 037H ;接收到的紅外遙控系統(tǒng)碼(客戶碼)反碼
MA3 EQU 038H ;接收到的紅外遙控數(shù)據(jù)碼
MA4 EQU 039H ;接收到的紅外遙控數(shù)據(jù)碼反碼
HWJS EQU 03AH ;每10毫秒減1，直到為0，為0時清除“接收到的紅外遙控數(shù)據(jù)碼”，防止接收到別的連續(xù)碼產(chǎn)生誤動作。
ZRFJG EQU 03BH ;1:自然風變化時的檔位下限；2=檔位上限；3=檔位變化的間隔時間。設置時用
FENGMQ EQU 03CH ;蜂鳴器鳴響時長（*10毫秒），每10毫秒減1直到為0，0=蜂鳴器不響
ZDJS EQU 03DH ;中斷計數(shù)，蜂鳴器處理用
YSPWM EQU 03EH ;延時PWM驅(qū)動（*10毫秒），先全功率驅(qū)動繼電器，每10毫秒減1，為0時轉(zhuǎn)為PWM方式驅(qū)動
FWBZ1 EQU 03FH ;復位判斷標志1，也作EEPROM數(shù)據(jù)判斷標志
FWBZ2 EQU 040H ;復位判斷標志2，也作EEPROM數(shù)據(jù)判斷標志
DANG_G EQU 041H ;自然風(睡眠風)變化時的檔位上限
DANG_D EQU 042H ;自然風(睡眠風)變化時的檔位下限
SMFJG EQU 043H ;自然風(睡眠風)檔位變化的間隔時間(秒)
DANG EQU 044H ;正常風檔位
ANJZ EQU 045H ;紅外遙控編碼首地址，系統(tǒng)碼(客戶碼)，6個鍵的數(shù)據(jù)碼+數(shù)據(jù)碼反碼使用此地址后面12個字節(jié)
;--------------- 輔助寄存器、EEPROM寄存器地址 ---------------
AUXR EQU 08EH ;輔助寄存器
IAP_DATA EQU 0C2H ;數(shù)據(jù)寄存器，讀出、寫入的數(shù)據(jù)放在此處
IAP_ADDRH EQU 0C3H ;地址寄存器高八位
IAP_ADDRL EQU 0C4H ;地址寄存器低八位
IAP_CMD EQU 0C5H ;命令寄存器，0=關閉，1=讀，2=寫，3=擦除
IAP_TRIG EQU 0C6H ;命令觸發(fā)寄存器
IAP_CONTR EQU 0C7H ;控制寄存器
IAP_TPS EQU 0F5H ;等待時間控制寄存器
;======================= 程序代碼開始 =======================
ORG 0000H
LJMP START
ORG 000BH ;定時器0中斷
LJMP INTT0 ;定時器0中斷
ORG 001BH ;定時器1中斷
LJMP INTT1 ;定時器1中斷
ORG 0100H ;程序代碼從0100H開始
;--------------- 定時器0，25微秒產(chǎn)生一次中斷，控制繼電器、LED指示燈、蜂鳴器 ---------------
INTT0:
PUSH ACC
PUSH PSW
LCALL Control ;控制繼電器
JNB FLQH,INTT01 ;如果“風類切換”是0（正常風）就轉(zhuǎn)移
CLR LED ;是自然風狀態(tài)，點亮LED指示燈
INTT01:
CPL PWMBZ ;“PWM電平狀態(tài)標志”取反。PWM周期25微秒*2=50微秒，20KHz占空比50%
MOV A,ZDJS ;中斷計數(shù)
JZ INTT02 ;為0就轉(zhuǎn)移，每5次（25微秒*5=125微秒）執(zhí)行一次蜂鳴器處理。
DEC ZDJS ;減1
LJMP INTT04 ;
INTT02:
MOV ZDJS,#4 ;重新放入計數(shù)（5次）
MOV A,FENGMQ ;蜂鳴器鳴響時長
JZ INTT03 ;如果是0（不響）就轉(zhuǎn)移
CPL BUZZER ;取反，驅(qū)動無源蜂鳴器發(fā)聲。周期125微秒*2=250微秒，4KHz占空比50%
LJMP INTT04
INTT03:
SETB BUZZER ;置蜂鳴器控制端口為高電平（不響）
INTT04:
POP PSW
POP ACC
RETI
;--------------- 定時器1，1毫秒產(chǎn)生一次中斷，時間、顯示處理 ---------------
INTT1:
PUSH ACC
PUSH B
PUSH PSW
SETB RS1 ;RS1、RS0組合為11，選擇03組工作寄存器(R0~R7地址為18H~1FH)，退
SETB RS0 ;出中斷時會自動恢復原默認的第0組工作寄存器(R0~R7地址為00H~07H)
MOV A,HM ;毫秒計數(shù)
JZ INTT10 ;如果是0就轉(zhuǎn)移，每10毫秒執(zhí)行一次顯示、時間處理子程序
DEC HM ;減1
LJMP INTT11
INTT10:
MOV HM,#9 ;重新放入計數(shù)值（10毫秒）
LCALL TIME ;時間處理
LCALL DISPLAY ;顯示處理
INTT11:
POP PSW
POP B
POP ACC
RETI
;--------------- 定時器T0、T1設置 ----------------
SETINT:
ORL AUXR,#0C0H ;定時器T0、T1時鐘1T模式
ANL TMOD,#00H ;設置定時器T0、T1模式為16位自動重載
MOV TL0,#0ECH ;設置定時0初始值（25微秒）
MOV TH0,#0FEH ;設置定時0初始值（25微秒）
MOV TL1,#0CDH ;設置定時1初始值（1毫秒）
MOV TH1,#0D4H ;設置定時1初始值（1毫秒）
CLR TF1 ;清除TF1標志
SETB TR1 ;定時器1開始計時
SETB ET1 ;允許定時器1中斷
CLR TF0 ;清除TF0標志
SETB TR0 ;定時器0開始計時
SETB ET0 ;允許定時器0中斷
SETB PT0 ;設置定時器0中斷為最高優(yōu)先級
SETB EA ;允許全局中斷
RET
;*********************************** 主程序開始 ***********************************
START:
MOV P1M0,#00H ;設置P1為雙向口模式
MOV P1M1,#00H ;
MOV P3M0,#00H ;設置P3為雙向口模式
MOV P3M1,#00H ;
MOV P5M0,#00H ;設置P5為雙向口模式
MOV P5M1,#00H ;
MOV SP,#0C0H ;設置堆棧指針
MOV A,FWBZ1 ;檢查復位判斷標志，RAM數(shù)據(jù)不變就跳過初始化繼續(xù)運行
CJNE A,#0C8H,START1 ;檢查復位判斷標志，RAM數(shù)據(jù)不變就跳過初始化繼續(xù)運行
MOV A,FWBZ2 ;檢查復位判斷標志，RAM數(shù)據(jù)不變就跳過初始化繼續(xù)運行
CJNE A,#0D9H,START1 ;檢查復位判斷標志，RAM數(shù)據(jù)不變就跳過初始化繼續(xù)運行
MOV FWBZ0,#10 ;放入復位提示，閃爍顯示時長（秒）
LCALL SETINT ;定時器設置
LJMP START3 ;跳過初始化繼續(xù)運行
START1:
CLR A ;初始化，RAM從20H開始清零50H個字節(jié)
MOV R0,#50H ;初始化，RAM從20H開始清零50H個字節(jié)
MOV R1,#20H ;初始化，RAM從20H開始清零50H個字節(jié)
START2:
MOV @R1,A ;初始化，RAM從20H開始清零50H個字節(jié)
INC R1 ;初始化，RAM從20H開始清零50H個字節(jié)
DJNZ R0,START2 ;
SETB PWM ;PWM標志置為1，使用PWM方式驅(qū)動，如果用可控硅控制就取消這條指令或改為“CLR PWM”(禁止PWM驅(qū)動)
MOV FWBZ1,#0C8H ;初始化，放入復位及EEPROM判斷標志1到RAM
MOV FWBZ2,#0D9H ;初始化，放入復位及EEPROM判斷標志2到RAM
MOV FENGMQ,#12 ;上電蜂鳴器響一聲，鳴響時長12*10毫秒=120毫秒
LCALL SDMRDS ;置上電默認定時時間
MOV SMGLD,#3 ;置數(shù)碼管亮度為3級（8級亮度最高）
MOV DSDWJG,#3 ;定時與檔位交替顯示的間隔時間(秒)
MOV SMFJG,#2 ;睡眠風(自然風)漸慢/漸快檔位變化的間隔時間(秒)，如果EEPROM保存有設置值，將替換此默認設置
MOV DANG,#15 ;正常風檔位（1~15），如果EEPROM保存有設置值，將替換此默認設置
MOV DANG_G,#5 ;自然風變化時最高檔位上限（4~15），如果EEPROM保存有設置值，將替換此默認設置
MOV DANG_D,#1 ;自然風變化時最低檔位下限（1~12），如果EEPROM保存有設置值，將替換此默認設置
LCALL SETINT ;初始化，定時器設置
LCALL REEP ;讀EEPROM保存的各項設置，沒有就保存當前的設置值
START3:
CLR XSKG ;“顯示開關”置為0，允許T1中斷的顯示功能
CLR XSQHY ;“顯示切換1”置為0，顯示檔位、定時時間
LCALL HWYKCL ;調(diào)用紅外遙控處理子程序
LCALL SKEY ;掃描編碼器按鍵
JC START4 ;有按鍵動作（C=1）就轉(zhuǎn)移
LCALL Scan1 ;掃描編碼器
JNB BMQDZ,START5 ;編碼器沒有動作（BMQDZ=0）就轉(zhuǎn)移
LCALL BMQCL ;調(diào)用編碼器旋轉(zhuǎn)動作處理子程序
LJMP START3
START4:
LCALL AJDZCL ;調(diào)用按鍵動作處理子程序
LJMP START3
START5:
JNB YSBC,START3 ;如果“延時保存”為0（不需保存當前檔位值）就轉(zhuǎn)移
MOV A,MJS ;裝入倒計時
JNZ START3 ;不是0就轉(zhuǎn)移
CLR YSBC ;時間到，“延時保存”置為0
LCALL WEEP ;保存當前檔位值
LJMP START3
;*********************************** 主程序結(jié)束 ***********************************
;
;--------------- 設置上電默認定時 ---------------
SDMRDS:
MOV DSSJS,#8 ;小時
RET
;--------------- 設置“延時PWM驅(qū)動”時間 ---------------
;先全功率驅(qū)動繼電器，延時結(jié)束后轉(zhuǎn)為PWM方式驅(qū)動，降低功耗減少繼電器發(fā)熱量。
;繼電器吸合速度正常為幾毫秒至幾十毫秒。PWM方式驅(qū)動改為禁止后，“延時PWM驅(qū)動”無意義
SETPWM:
MOV YSPWM,#10 ;延時時間（*10毫秒），10*10=100毫秒
RET
;-------------------------------------------------------------------------------
;紅外遙控處理子程序
;1“關”鍵：定時時間清零，關風扇
;2“開/風速”鍵：定時時間為零時，置上電默認定時時間，開風扇；定時時間不為零時，檔位
; 加1，到最高檔后又從1檔開始循環(huán)，支持長按連續(xù)加；
; 自然風(睡眠風)狀態(tài)時不能調(diào)整檔位。
;3“定時”鍵：增加定時時間。在關的狀態(tài)時，增加定時時間立即開風扇。支持長按連續(xù)加。
;4“睡眠”鍵：正常風與自然風(睡眠風)切換，自然風狀態(tài)時LED指示燈亮，只顯示定時時間。
;5“+”鍵：對當前顯示的“定時時間”或“檔位”作增加調(diào)整，支持長按連續(xù)加。
;6“-”鍵：對當前顯示的“定時時間”或“檔位”作減少調(diào)整，支持長按連續(xù)減。
;-------------------------------------------------------------------------------
HWYKCL:
LCALL JIEMA ;調(diào)用紅外遙控解碼子程序
JC YKCL1 ;解碼成功（C=1）就轉(zhuǎn)移
YKCL0:
RET
YKCL1:
MOV R5,A ;解碼子程序返回的參數(shù)暫時放到R5
MOV A,MA1 ;裝入當前接收到的系統(tǒng)碼到A
MOV B,ANJZ ;裝入原來保存的系統(tǒng)碼到B
CJNE A,B,YKCL0 ;不同就轉(zhuǎn)移退出
MOV R0,#ANJZ ;按鍵值首地址
INC R0 ;地址加1
MOV R3,#6 ;共搜索6個按鍵值
MOV R7,#1 ;功能編號
YKCL2:
MOV A,MA3 ;裝入數(shù)據(jù)碼
MOV B,@R0 ;裝入原來的數(shù)據(jù)碼
CJNE A,B,YKCL3 ;不同就轉(zhuǎn)移，檢查下一個
INC R0 ;相同，地址加1，檢查反碼是否相同
MOV A,MA4 ;裝入數(shù)據(jù)碼反碼
MOV B,@R0 ;裝入數(shù)據(jù)碼反碼
DEC R0 ;地址減1
CJNE A,B,YKCL3 ;不同就轉(zhuǎn)移，檢查下一個
LJMP YKCL4 ;搜索到了
YKCL3:
INC R0 ;地址加1
INC R0 ;地址加1
INC R7 ;功能編號加1
DJNZ R3,YKCL2 ;如果未檢查完就轉(zhuǎn)移繼續(xù)
RET ;未搜索到，退出
YKCL4:
LCALL SETPWM ;設置“延時PWM驅(qū)動”時間
MOV A,R5 ;解碼子程序返回的參數(shù)
JNZ YKCL41 ;如果是連續(xù)碼（1）就轉(zhuǎn)移
MOV FENGMQ,#12 ;蜂鳴器響一聲，12*10毫秒=120毫秒
YKCL41:
MOV A,R7 ;功能編號放入A
CJNE A,#1,YKCL5 ;不是1（關）就轉(zhuǎn)移
LCALL DSSJQL ;定時時間清零，關風扇
CLR XSNRXZ ;“顯示內(nèi)容選擇”置為0，顯示定時時間
RET
YKCL5:
CJNE A,#2,YKCL8 ;不是2（開/風速）就轉(zhuǎn)移
MOV A,DSSJS ;檢查定時時間是否為0
JNZ YKCL6 ;不為0就轉(zhuǎn)移
MOV A,DSSJF ;檢查定時時間是否為0
JNZ YKCL6 ;不為0就轉(zhuǎn)移
MOV A,DSSJM ;檢查定時時間是否為0
JNZ YKCL6 ;不為0就轉(zhuǎn)移
LCALL SDMRDS ;是0，放入上電默認定時時間，開風扇
MOV SHMJS,#150 ;設置持續(xù)按下“開/風速”等待1.5秒才響應連續(xù)碼
RET
YKCL6:
JB FLQH,YKCL12 ;如果“風類切換”為1睡眠風(自然風)就轉(zhuǎn)移退出
MOV A,SHMJS
JNZ YKCL12 ;如果時間未到就轉(zhuǎn)移退出，不響應
MOV SHMJS,#30 ;設置響應連續(xù)碼間隔時間(×10毫秒)
SETB XSNRXZ ;“顯示內(nèi)容選擇”置為1，顯示檔位
MOV A,DANG ;裝入當前檔位值
CJNE A,#15,YKCL7 ;不是最高檔（15）就轉(zhuǎn)移
MOV DANG,#0 ;是，改為0
YKCL7:
SETB XZFX ;“旋轉(zhuǎn)方向”置為1（+）
LCALL BMQCL ;加
RET
YKCL8:
CJNE A,#3,YKCL9 ;不是3（定時）就轉(zhuǎn)移
MOV A,SHMJS
JNZ YKCL12 ;如果時間未到就轉(zhuǎn)移退出，不響應
MOV SHMJS,#30 ;設置響應連續(xù)碼的間隔時間(×10毫秒)
CLR XSNRXZ ;“顯示內(nèi)容選擇”置為0，顯示定時時間
LJMP YKCL7
YKCL9:
CJNE A,#4,YKCL10 ;不是4睡眠風(自然風)就轉(zhuǎn)移
MOV A,SHMJS
JNZ YKCL12 ;如果時間未到就轉(zhuǎn)移退出，不響應
MOV SHMJS,#100 ;設置響應連續(xù)碼的間隔時間，1秒
CPL FLQH ;“風類切換”取反，正常風/自然風切換
RET
YKCL10:
CJNE A,#5,YKCL11 ;不是5(加+)就轉(zhuǎn)移
MOV A,SHMJS
JNZ YKCL12 ;如果時間未到就轉(zhuǎn)移退出，不響應
MOV SHMJS,#20 ;設置響應連續(xù)碼的間隔時間(×10毫秒)
SETB XZFX ;“旋轉(zhuǎn)方向”置為1（+）
LCALL BMQCL ;加
RET
YKCL11:
MOV A,SHMJS ;
JNZ YKCL12 ;如果時間未到就轉(zhuǎn)移退出，不響應
MOV SHMJS,#20 ;設置響應連續(xù)碼的間隔時間(×10毫秒)
CLR XZFX ;“旋轉(zhuǎn)方向”置為0（-）
LCALL BMQCL ;減
YKCL12:
RET
;--------------------------------------------------------------------------------------------
;子程序：紅外遙控解碼
;出口參數(shù)：
;C=1、A=0：解碼成功。
;C=1、A=1：連續(xù)碼。
;系統(tǒng)碼(客戶碼)放在MA1，系統(tǒng)碼(客戶碼)反碼放在MA2
;數(shù)據(jù)碼(按鍵值)放在MA3，數(shù)據(jù)碼(按鍵值)反碼放在MA4
;
;紅外接收頭實際輸出的NEC編碼格式：
;引導碼：9ms低電平+4.5ms高電平
;碼0：0.56ms低電平+0.56ms高電平
;碼1：0.56ms低電平+1.68ms高電平
;結(jié)束位：0.56ms低電平
;單鍵碼：引導碼+8位系統(tǒng)碼+8位系統(tǒng)碼反碼+8位數(shù)據(jù)碼+8位數(shù)據(jù)碼反碼+結(jié)束位
;連續(xù)碼：引導碼9ms低電平+2.25ms高電平+結(jié)束位0.56ms低電平
;
;有個別紅外遙控器并不是8位系統(tǒng)碼+8位系統(tǒng)碼反碼+8位數(shù)據(jù)碼+8位數(shù)據(jù)碼反碼的數(shù)據(jù)格式，
;而是這兩種情況：
;一、16位固定的系統(tǒng)碼(客戶碼)+8位數(shù)據(jù)碼+8位數(shù)據(jù)碼反碼
;二、24位固定的系統(tǒng)碼(客戶碼)+8位數(shù)據(jù)碼
;所以對解碼結(jié)果不作反碼檢驗
;
;43微秒延時子程序的數(shù)值是156，因T0中斷頻率高占用資源，使延時變長，修改為127才能正確解碼，
;如果移植到別的程序，沒有過高頻率的中斷，數(shù)值要改回156
;--------------------------------------------------------------------------------------------
JIEMA:
JB IR,JMerr ;IR為1(高電平)就轉(zhuǎn)移退出，無信號
MOV R7,#200 ;檢測200次×43微秒＝8600微秒(8.6毫秒)
JIEMA1:
LCALL DELAY43US ;延時43微秒
JB IR,JMerr ;如果出現(xiàn)高電平(IR為1)就轉(zhuǎn)移退出，不是有效信號
DJNZ R7,JIEMA1 ;重復200次
MOV R7,#20 ;未出現(xiàn)高電平，視為有效9毫秒引導碼，再檢測20次
JIEMA2:
LCALL DELAY43US ;延時43微秒
JB IR,JIEMA3 ;如果出現(xiàn)高電平(IR=1)就轉(zhuǎn)移
DJNZ R7,JIEMA2 ;重復20次×43微秒＝860微秒(0.86毫秒)
LJMP JMerr ;超時，退出，不是有效信號
JIEMA3:
MOV HWJS,#50 ;500毫秒計數(shù)，為0時清除“接收到的紅外遙控數(shù)據(jù)碼”，防止接收到別的連續(xù)碼產(chǎn)生誤動作。
MOV R7,#70 ;已變?yōu)楦唠娖剑?毫秒引導碼結(jié)束，檢測70次共3010微秒
JIEMA4:
LCALL DELAY43US ;延時43微秒
JNB IR,LXM ;出現(xiàn)低電平(IR=0)就視為是2.25毫秒連續(xù)碼
DJNZ R7,JIEMA4
MOV R7,#50 ;3.01毫秒內(nèi)未出現(xiàn)低電平，不是連續(xù)碼，再檢測50次
JIEMA5:
LCALL DELAY43US ;延時43微秒
JNB IR,JIEMA6 ;出現(xiàn)低電平(IR=0)就轉(zhuǎn)移，4.5毫秒引導碼高電平結(jié)束
DJNZ R7,JIEMA5 ;重復50次共2150微秒
LJMP JMerr ;超時，退出，不是有效信號
LXM:
SETB C ;是連續(xù)碼，把C置為1
MOV A,#1 ;是連續(xù)碼，把1放入A
RET
JIEMA6:
;--- 引導碼9ms低電平+4.5ms高電平結(jié)束 ---
MOV R1,#MA1 ;存放編碼的首地址放入R1
MOV R5,#4 ;共4個字節(jié)數(shù)據(jù)
JIEMA7:
MOV R6,#8 ;每個字節(jié)為8位
JIEMA8:
MOV R7,#20 ;檢測20次×43微秒＝860微秒(0.86毫秒)，要大于0.56毫秒
JIEMA9:
LCALL DELAY43US ;延時43微秒
JB IR,JIEMA10 ;如果IR是1(高電平)就轉(zhuǎn)移
DJNZ R7,JIEMA9 ;時間未到就繼續(xù)檢測，等待低電平信號結(jié)束
LJMP JMerr ;超時，退出
JIEMA10:
MOV R7,#20 ;變?yōu)楦唠娖搅耍訒r20次共860微秒(0.86毫秒)
JIEMA11:
LCALL DELAY43US
DJNZ R7,JIEMA11 ;延時0.86毫秒
MOV C,IR ;延時結(jié)束IR的電平就是數(shù)據(jù)信號(0或1)，移入C中
JNB IR,JIEMA13 ;如果IR是0(低電平)就轉(zhuǎn)移
MOV R7,#50 ;是高電平，檢測50次×43微秒＝2150微秒(2.15毫秒)
JIEMA12:
LCALL DELAY43US ;
JNB IR,JIEMA13 ;如果IR是0(低電平)就轉(zhuǎn)移，
DJNZ R7,JIEMA12 ;時間未到就繼續(xù)檢測，等待高電平信號結(jié)束
LJMP JMerr ;超時，退出
JIEMA13:
MOV A,@R1 ;裝入R1指向的RAM地址的數(shù)據(jù)到A寄存器
RRC A ;將C中的值（0或1）移入A中的最低位
MOV @R1,A ;把A中的數(shù)據(jù)放回R1指向的RAM
DJNZ R6,JIEMA8 ;如果未接收完8位就轉(zhuǎn)移繼續(xù)
INC R1 ;接收完8位了，地址加1
DJNZ R5,JIEMA7 ;如果4個字節(jié)數(shù)據(jù)未接收完就轉(zhuǎn)移繼續(xù)
JMok:
SETB C ;把C置為1，解碼成功
CLR A ;把A置為0，解碼成功
RET
JMerr:
CLR C ;把C置為0，解碼不成功
RET
;------------ 延時43微秒 ------------
DELAY43US: ;@11.0592MHz
PUSH 12H
MOV 12H,#127 ;延時43微秒的數(shù)值是156，因T0中斷頻率高占用資源，使延時變長，修改為此數(shù)
NEXT43: ;值才能正確解碼，如果移植到別的程序，沒有過高頻率的中斷，此數(shù)值要改回156
DJNZ 12H,NEXT43
POP 12H
RET
;------------------------------------------------------------------------------------------------
;子程序：EC11編碼器按鍵動作處理
; 1.短按1次：正常風與睡眠風(自然風)切換。睡眠風狀態(tài)時LED指示燈亮，只顯示定時時間。
; 2.短按2次：設置睡眠風(自然風)漸慢/漸快變化的上下限檔位范圍、檔位變化時的間隔時間(秒)
; 3.長按10秒：顯示“----”，紅外線遙控信號解碼，遙控器按鍵的功能定義，定義好后須長按10秒才保存
;
;紅外遙控器的按鍵定義：
;定義1“關”、2“開/風速”、3“定時”、4“睡眠”、5“+”、6“－”六個功能鍵。
; 交替顯示功能編號+遙控器客戶碼和原來保存的按鍵值，按鍵值為數(shù)據(jù)碼+數(shù)據(jù)碼反碼4個十
;六進制數(shù)，按下遙控器按鍵收到信號解碼成功并顯示，即為新的按鍵值，遙控器客戶碼與原來保
;存的不相同時，自動刪除舊的數(shù)據(jù)(保存才會生效)，短按跳到下一個功能編號，也可以旋轉(zhuǎn)EC11
;編碼器向前/后跳到任意功能編號，全部或部分定義好后，長按10秒顯示“----”保存并退出才生
;效，短按兩次退出或60秒無操作自動退出，不保存，仍然還是原來的數(shù)據(jù)。
;-------------------------------------------------------------------------------------------------
AJDZCL:
LCALL KEY ;調(diào)用編碼器按鍵開關處理子程序
CJNE A,#1,AJDZ2 ;如果不是按下1次就轉(zhuǎn)移
CPL FLQH ;“風類切換”取反，正常風/自然風切換
RET
AJDZ2:
CJNE A,#2,AJDZ3 ;如果不是按下2次就轉(zhuǎn)移
LCALL ZRFFW ;調(diào)用自然風變化檔位上下限范圍、檔位變化間隔時間設置子程序
RET
AJDZ3:
SETB XSQHY ;是長按10秒，“顯示切換1”置為1，顯示紅外解碼或自然風檔位變化范圍
CLR XSQHE ;“顯示切換2”置為0，紅外遙控信號解碼顯示
MOV XMBH,#1 ;先放入項目編號1（關）
LCALL HENGX ;關閉T0中斷的顯示功能，顯示“----”
LCALL KEYEX ;等待按鍵釋放
CLR XSKG ;“顯示開關”置為0，恢復T1中斷的顯示功能
AJDZ4:
CLR BMXSQH ;“編碼顯示切換”置為0，先顯示功能編號+系統(tǒng)碼
AJDZ5:
MOV MJS,#60 ;設置無信號等待時間（秒）
MOV DSDW,#2 ;設置系統(tǒng)碼和數(shù)據(jù)碼交替顯示間隔時間（秒）
AJDZ6:
MOV FWBZ0,#0 ;把0放入到FWBZ0，不閃爍顯示
AJDZ7:
LCALL JIEMA ;調(diào)用紅外遙控解碼子程序
JC LXMPD ;解碼成功（C=1）就轉(zhuǎn)移
LCALL SKEY ;掃描編碼器按鍵
JNC AJDZ11 ;沒有按鍵動作(C=0)就轉(zhuǎn)移
MOV FWBZ0,#0 ;把0放入到FWBZ0，不閃爍顯示
LCALL KEY ;有按鍵動作，調(diào)用編碼器按鍵處理子程序
CJNE A,#3,AJDZ9 ;如果不是3（長按10秒）就轉(zhuǎn)移
AJDZ8:
LCALL WEEP ;保存當前設置
LCALL HENGX ;關閉T0中斷的顯示功能，顯示“----”
LCALL KEYEX ;等待按鍵釋放
CLR XSKG ;“顯示開關”置為0，恢復T1中斷的顯示功能
RET
LXMPD:
JZ AJDZ17 ;如果A=0（不是連續(xù)碼）就轉(zhuǎn)移
LJMP AJDZ5
AJDZ9:
CJNE A,#1,AJDZ_Q ;如果不是1（短按1次）就轉(zhuǎn)移退出，不保存
AJDZ90:
MOV A,XMBH ;裝入項目編號
CJNE A,#6,AJDZ10 ;如果不是最后一項就轉(zhuǎn)移
MOV XMBH,#0
AJDZ10:
INC XMBH ;加1，跳到下一個功能編號
LJMP AJDZ4
AJDZ11:
LCALL Scan1 ;掃描編碼器（有方向標志）
JB BMQDZ,AJDZ15 ;編碼器有動作(1)就轉(zhuǎn)移
MOV A,DSDW ;沒有轉(zhuǎn)動，裝入交替顯示間隔時間（秒）到寄存器A
JNZ AJDZ12 ;不為0就轉(zhuǎn)移
CPL BMXSQH ;為0，“編碼顯示切換”取反，顯示另一項
MOV DSDW,#1 ;設置系統(tǒng)碼和數(shù)據(jù)碼交替顯示間隔時間（秒）
AJDZ12:
MOV A,MJS ;裝入無信號等待時間到寄存器A
JNZ AJDZ13 ;不為0就轉(zhuǎn)移
AJDZ_Q:
LCALL RE00 ;讀EEPROM保存的數(shù)據(jù)
MOV FWBZ0,#0 ;把0放入到FWBZ0，不閃爍顯示，退出，不保存
RET
AJDZ13:
CJNE A,#6,AJDZ14 ;檢查剩余時間
AJDZ14:
JNC AJDZ6 ;等于或大于就轉(zhuǎn)移，不閃爍顯示
MOV FWBZ0,A ;剩余時間放到FWBZ0，閃爍顯示
LJMP AJDZ7
AJDZ15:
LCALL Scan2 ;掃描編碼器（無方向標志）
JB BMQDZ,AJDZ15 ;旋轉(zhuǎn)動作未結(jié)束(1)就轉(zhuǎn)移繼續(xù)等待
JB XZFX,AJDZ90 ;順時針正轉(zhuǎn)(1）就轉(zhuǎn)移
MOV A,XMBH ;反轉(zhuǎn)，裝入項目編號
DEC A ;減1
JNZ AJDZ16 ;不為0就轉(zhuǎn)移
MOV A,#6 ;跳到第6項
AJDZ16:
MOV XMBH,A
LJMP AJDZ4
;
AJDZ17:
SETB BMXSQH ;“編碼顯示切換”置為1（顯示數(shù)據(jù)碼+反碼）
MOV A,MA1 ;裝入當前接收到的系統(tǒng)碼到A
MOV B,ANJZ ;裝入原來保存的系統(tǒng)碼到B
CJNE A,B,AJDZ20 ;不同就轉(zhuǎn)移
MOV R0,#ANJZ ;遙控編碼首地址
INC R0 ;地址加1
MOV R3,#6 ;檢查6個按鍵值，發(fā)現(xiàn)有相同的就刪除（清零）
AJDZ18:
MOV A,MA3 ;裝入數(shù)據(jù)碼
MOV B,@R0 ;裝入原來的數(shù)據(jù)碼
CJNE A,B,AJDZ19 ;不同就轉(zhuǎn)移，檢查下一個
INC R0 ;相同，地址加1，檢查反碼看是否也相同
MOV A,MA4 ;裝入數(shù)據(jù)碼反碼
MOV B,@R0 ;裝入數(shù)據(jù)碼反碼
DEC R0 ;地址減1
CJNE A,B,AJDZ19 ;不同就轉(zhuǎn)移，檢查下一個
MOV @R0,#0 ;也相同，數(shù)據(jù)碼位置放入0
INC R0 ;地址加1
MOV @R0,#0 ;反碼位置放入0
DEC R0 ;地址減1
AJDZ19:
INC R0 ;地址加1
INC R0 ;地址加1
DJNZ R3,AJDZ18 ;如果未檢查完就轉(zhuǎn)移繼續(xù)
LJMP AJDZ22
AJDZ20:
MOV ANJZ,MA1 ;移入新的系統(tǒng)碼
MOV R0,#ANJZ ;原來的數(shù)據(jù)全部清零
MOV R3,#12 ;原來的數(shù)據(jù)全部清零
AJDZ21:
INC R0 ;原來的數(shù)據(jù)全部清零
MOV @R0,#0 ;原來的數(shù)據(jù)全部清零
DJNZ R3,AJDZ21 ;原來的數(shù)據(jù)全部清零
AJDZ22:
MOV A,XMBH ;裝入項目編號
MOV B,#2 ;項目編號乘2
MUL AB ;項目編號乘2
DEC A ;計算結(jié)果減1
ADD A,#ANJZ ;加遙控編碼首地址
MOV R0,A ;得出數(shù)據(jù)碼的實際地址
MOV @R0,MA3 ;把接收到的數(shù)據(jù)移到對應的按鍵值RAM地址
INC R0 ;把接收到的數(shù)據(jù)移到對應的按鍵值RAM地址
MOV @R0,MA4 ;把接收到的數(shù)據(jù)移到對應的按鍵值RAM地址
LJMP AJDZ5
;---------------------------------------------------------------------------------
;子程序：設置調(diào)整睡眠風(自然風)變化的檔位上下限范圍、變化時的間隔時間(秒)
; 1.顯示：L-最低檔位下限
; 2.顯示：H-最高檔位上限
; 3.顯示：E-檔位變化時的間隔時間(秒)
;短按編碼器按鍵，跳到另一項；短按2次編碼器按鍵保存并退出；無操作5秒后開始閃爍顯示，
;閃爍顯示5秒跳到下一項，如果在第3項，閃爍顯示5秒無操作則保存并退出。
;上、下限檔位之間最少間隔3檔。自然風檔位變化的間隔時間為1~5秒
;---------------------------------------------------------------------------------
ZRFFW:
SETB XSQHY ;“顯示切換1”置為1，顯示紅外解碼或自然風檔位變化范圍
SETB XSQHE ;“顯示切換2”置為1，顯示自然風檔位變化范圍
MOV ZRFJG,#1 ;先設為第一項，檔位下限
ZRFFW1:
MOV A,ZRFJG ;裝入項目號
DEC A ;減1
JNZ ZRFFW2 ;不為0就轉(zhuǎn)移
LCALL ZRFXX ;是1，設置下限檔位調(diào)整時的最大和最小值、調(diào)整對象的地址
LJMP SZTZ
ZRFFW2:
DEC A ;減1
JNZ ZRFFW3 ;不為0就轉(zhuǎn)移
LCALL ZRFSX ;是2，設置上限檔位調(diào)整時的最大和最小值、調(diào)整對象的地址
LJMP SZTZ
ZRFFW3:
MOV R5,#1 ;是3，檔位變化的間隔時間(秒)，調(diào)整時的最小值
MOV R6,#5 ;是3，檔位變化的間隔時間(秒)，調(diào)整時的最大值
MOV R0,#SMFJG ;檔位變化的間隔時間(秒)地址
SZTZ:
MOV MJS,#10 ;無操作等待時間10秒
SZTZ1:
MOV FWBZ0,#0 ;把0放入到FWBZ0，不閃爍顯示
SZTZ2:
LCALL SKEY ;掃描編碼器按鍵開關
JNC SZTZ5 ;沒有按鍵動作(C=0)就轉(zhuǎn)移
LCALL KEY ;有按鍵動作，調(diào)用編碼器按鍵處理子程序
CJNE A,#2,SZTZ3
SZTZ3:
JNC SZTZ4 ;如果是按下2次及以上就轉(zhuǎn)移
SZTZ30:
INC ZRFJG ;是按下1次，項目號加1（跳到下一項）
MOV A,ZRFJG ;裝入項目號
CJNE A,#4,SZTZ31 ;是否小于4
SZTZ31: JC ZRFFW1 ;小于就轉(zhuǎn)移
LJMP ZRFFW ;等于或大于，轉(zhuǎn)移，設為第一項
SZTZ4:
LCALL WEEP ;保存
MOV FWBZ0,#0 ;把0放入到FWBZ0，不閃爍顯示
LCALL KEYEX ;等待按鍵釋放
RET
SZTZ5:
LCALL Scan1 ;掃描編碼器（有方向標志）
JB BMQDZ,SZTZ8 ;編碼器已經(jīng)轉(zhuǎn)動（1）就轉(zhuǎn)移
MOV A,MJS ;沒有轉(zhuǎn)動，裝入秒計數(shù)到寄存器A
JZ SZTZ7 ;如果秒計數(shù)為0(10秒無操作)就轉(zhuǎn)移
CJNE A,#6,SZTZ6 ;檢查剩余時間
SZTZ6:
JNC SZTZ1 ;等于或大于就轉(zhuǎn)移，不閃爍顯示
MOV FWBZ0,A ;剩余時間放到FWBZ0，閃爍顯示
LJMP SZTZ2
SZTZ7:
MOV A,ZRFJG ;時間到，裝入項目號
CJNE A,#3,SZTZ30 ;不是最后一項就轉(zhuǎn)移，跳到下一項
LJMP SZTZ4 ;轉(zhuǎn)移，保存并退出
SZTZ8:
LCALL Scan2 ;掃描編碼器（無方向標志）
JB BMQDZ,SZTZ8 ;旋轉(zhuǎn)動作未結(jié)束（1）就轉(zhuǎn)移繼續(xù)等待
JB XZFX,SZTZ11 ;是順時針正轉(zhuǎn)（1）就轉(zhuǎn)移
MOV B,R5 ;是反轉(zhuǎn)，裝入最小值到B寄存器
MOV A,@R0 ;裝入R0指向的RAM地址的調(diào)整對象數(shù)值
DEC A ;減1
CJNE A,B,SZTZ9 ;與最小比較
SZTZ9:
JC SZTZ10 ;如果小于就轉(zhuǎn)移
MOV @R0,A ;等于或大于，把減1后的結(jié)果放回去
LJMP SZTZ
SZTZ10:
MOV @R0,B ;直接放入最小值
LJMP SZTZ
SZTZ11:
MOV B,R6 ;裝入最大值到B寄存器
MOV A,@R0 ;裝入R0指向的RAM地址的調(diào)整對象數(shù)值
INC A ;加1
CJNE A,B,SZTZ12 ;加完后與最大值比較
SZTZ12:
JC SZTZ13 ;如果小于就轉(zhuǎn)移
MOV @R0,B ;等于或大于，直接放入最大值
LJMP SZTZ
SZTZ13:
MOV @R0,A ;小于最大值，把加1后的結(jié)果放回去
LJMP SZTZ
;---------------------------------------------------------------------------
;設置睡眠風(自然風)變化范圍的上限檔位，最大為15檔，最小為下限檔位加3檔
;---------------------------------------------------------------------------
ZRFSX:
MOV B,#15 ;調(diào)整時的最大值
MOV A,DANG_D ;裝入當前檔位下限
ADD A,#3 ;加3檔
CJNE A,B,ZRFSX1 ;是否等于或大于上限
ZRFSX1:
JC ZRFSX2 ;小于就轉(zhuǎn)移
MOV A,B
PUSH ACC
SUBB A,#3 ;等于或大于，把檔位下限改為最大值減3檔
MOV DANG_D,A ;等于或大于，把檔位下限改為最大值減3檔
POP ACC
ZRFSX2:
MOV R5,A ;調(diào)整時的最小值
MOV R6,B ;調(diào)整時的最大值
MOV R0,#DANG_G ;自然風檔位上限地址
RET
;---------------------------------------------------------------------------
;設置睡眠風(自然風)變化范圍的下限檔位，最小為1檔，最大為上限檔位減3檔
;---------------------------------------------------------------------------
ZRFXX:
MOV B,#4 ;調(diào)整時的最小值1加3檔
MOV A,DANG_G ;裝入當前自然風檔位上限
CJNE A,B,ZRFXX1
ZRFXX1:
JC ZRFXX2 ;小于就轉(zhuǎn)移
SUBB A,#3 ;等于或大于，檔位上限減3檔即為調(diào)整時的最大值
MOV B,A ;等于或大于，檔位上限減3檔即為調(diào)整時的最大值
LJMP ZRFXX3
ZRFXX2:
MOV DANG_G,B ;小于最小值+3檔，把上限檔位改為最小值加3檔
MOV B,#1
ZRFXX3:
MOV R5,#1 ;調(diào)整時的最小值
MOV R6,B ;調(diào)整時的最大值
MOV R0,#DANG_D ;自然風檔位下限地址
RET

復制代碼

;------------------------------------------------------------------------------------
;子程序：編碼器按鍵開關處理，間隔時間不超過0.6秒的2次短按，為有效按鍵動作
;出口參數(shù)：A=1(按了1次)；A=2(按了2次)；A=3(長按達到了10秒)
;------------------------------------------------------------------------------------
KEY:
MOV MJS,#10 ;放入等待時間(秒)
MOV FENGMQ,#12 ;蜂鳴器響一聲，12*10毫秒=120毫秒
KEY1:
MOV A,MJS ;裝入等待時間
JNZ KEY2 ;如果不為0就轉(zhuǎn)移，時間未到
MOV A,#3 ;時間到了
RET
KEY2:
LCALL SKEY ;掃描按鍵
JC KEY1 ;如果C=1(按鍵還沒松開)，就繼續(xù)掃描
LCALL KEYA ;掃描按鍵600毫秒
JZ KEY3 ;如果600毫秒內(nèi)有按鍵動作就轉(zhuǎn)移
MOV A,#1 ;600毫秒內(nèi)沒有按鍵動作，置A=1(按了1次)
RET
KEY3:
MOV FENGMQ,#12 ;蜂鳴器響一聲，12*10毫秒=120毫秒
LCALL KEYEX ;等待第二次按鍵松開
MOV A,#2 ;置A=2(按了2次)
RET
;----------- 掃描按鍵600毫秒，有按鍵動作A=0，無按鍵動作A=1 -----------
KEYA:
MOV SHMJS,#60 ;等待600毫秒
KEYB:
MOV A,SHMJS ;裝入(10)毫秒計數(shù)
JZ KEYC ;為0（時間到）就轉(zhuǎn)移
LCALL SKEY ;掃描按鍵
JNC KEYB ;沒有按鍵動作(C=0)就轉(zhuǎn)移
CLR A ;有按鍵動作A=0
RET
KEYC:
MOV A,#1 ;等待時間已到，A=1沒有按鍵動作
RET
;-------------- 按鍵開關掃描，未按C=0，已按下C=1 --------------
SKEY:
SETB EC11K ;按鍵端口置為高電平
JNB EC11K,SKEY1 ;為0(低電平)就轉(zhuǎn)移
CLR C ;C置為0，沒有按鍵動作
RET
SKEY1:
LCALL DELAY20 ;延時20毫秒
SETB EC11K ;延時結(jié)束后再次把按鍵端口置為高電平
JNB EC11K,SKEY2 ;為0(低電平)就轉(zhuǎn)移
CLR C ;C置為0，沒有按鍵動作
RET ;按鍵未被有效按下，退出
SKEY2:
SETB C ;C置為1，按鍵已有效按下
LCALL SETPWM ;有按鍵動作就重新放置“延時PWM驅(qū)動”時間
RET
;------------------ 等待按鍵釋放 ------------------
KEYEX:
LCALL SKEY ;掃描按鍵
JC KEYEX ;如果C=1(按鍵還沒釋放)就繼續(xù)掃描
RET
;------------------ 延時20毫秒 ------------------
DELAY20: ;@11.0592MHz
PUSH 15H
PUSH 16H
PUSH 17H
MOV 15H,#2
MOV 16H,#32
MOV 17H,#58
NEXT20:
DJNZ 17H,NEXT20
DJNZ 16H,NEXT20
DJNZ 15H,NEXT20
POP 17H
POP 16H
POP 15H
RET
;---------------------------------------------------------------------------------------------
;子程序：編碼器旋轉(zhuǎn)動作處理，根據(jù)旋轉(zhuǎn)方向增(減)定時時間、檔位
;10小時以下每次增(減)30分鐘；10小時及以上每次增(減)1個小時；20小時以上每次增(減)2個小時
;---------------------------------------------------------------------------------------------
BMQCL:
LCALL Scan2 ;掃描編碼器（無方向標志）
MOV DSDW,DSDWJG ;置交替顯示間隔時間
JB BMQDZ,BMQCL ;“編碼器動作”為1(動作未結(jié)束)就轉(zhuǎn)移繼續(xù)等待
BMQCL0:
JNB XSNRXZ,BMQCL5 ;“顯示內(nèi)容選擇”為0(顯示定時時間)就轉(zhuǎn)移
SETB YSBC ;“延時保存”置為1
MOV MJS,#10 ;“延時保存”時長（秒）。延時結(jié)束后才保存，避免頻繁的EEPROM操作
MOV A,DANG ;裝入當前檔位值
JB XZFX,BMQCL2 ;“旋轉(zhuǎn)方向”為1（順時針正轉(zhuǎn)）就轉(zhuǎn)移
DEC A ;是反轉(zhuǎn)，減1檔
JNZ BMQCL1 ;減1后不為0就轉(zhuǎn)移
RET
BMQCL1:
MOV DANG,A
RET
BMQCL2:
CJNE A,#15,BMQCL3 ;是否已到最高15檔
BMQCL3:
JC BMQCL4 ;小于就轉(zhuǎn)移
MOV DANG,#15 ;等于或大于，放入最高檔位15
RET
BMQCL4:
INC DANG ;還未到上限，增1檔
RET
BMQCL5:
CLR SSBZ ;“閃爍標志”置為0（數(shù)字及冒號狀態(tài)為“顯示”）
MOV A,DSSJS ;裝入定時時間（時）
CJNE A,#20,BMQCL6 ;當前“時”是否等于或大于20
BMQCL6:
JC BMQCL7 ;小于就轉(zhuǎn)移
MOV R5,#2 ;等于或大于20，加減2個小時
LJMP BMQCL9
BMQCL7:
CJNE A,#10,BMQCL8 ;當前“時”是否等于或大于10
BMQCL8:
JC BMQCL13 ;小于就轉(zhuǎn)移
MOV R5,#1 ;等于或大于10，加減1個小時
BMQCL9:
JNB XZFX,BMQCL11 ;“旋轉(zhuǎn)方向”為0（逆時針反轉(zhuǎn)）就轉(zhuǎn)移
ADD A,R5 ;是正轉(zhuǎn)，加
CJNE A,#100,BMQCL10 ;加完后是否等于或大于100
BMQCL10:
JC BMQCL12 ;如果小于就轉(zhuǎn)移，把A放回到DSSJS
MOV DSSJS,#99 ;已經(jīng)大于99了，直接設置為99:59:59+HMJS(1秒)，100小時
MOV DSSJF,#59 ;已經(jīng)大于99了，直接設置為99:59:59+HMJS(1秒)，100小時
MOV DSSJM,#59 ;已經(jīng)大于99了，直接設置為99:59:59+HMJS(1秒)，100小時
RET
BMQCL11:
SUBB A,R5 ;是反轉(zhuǎn)，減
BMQCL12:
MOV DSSJS,A ;把計算結(jié)果放入DSSJS
RET
BMQCL13:
MOV A,DSSJF ;小于10小時，裝入定時時間（分）
JNB XZFX,BMQCL16 ;“旋轉(zhuǎn)方向”為0（逆時針反轉(zhuǎn)）就轉(zhuǎn)移
ADD A,#30 ;是正轉(zhuǎn)，當前“分”加30
CJNE A,#60,BMQCL14 ;加完后“分”是否等于或大于60
BMQCL14:
JC BMQCL15 ;小于60就轉(zhuǎn)移，把A放入定時時間（分）
SUBB A,#60 ;等于或大于60，就減60，然后小時加1
INC DSSJS ;小時加1
BMQCL15:
MOV DSSJF,A ;把A放入定時時間（分）
RET
BMQCL16:
CJNE A,#30,BMQCL17 ;是逆時針反轉(zhuǎn)，當前“分”是否等于或大于30
BMQCL17:
JC BMQCL18 ;小于就轉(zhuǎn)移
SUBB A,#30 ;定時時間（分）減30
MOV DSSJF,A ;把計算結(jié)果放入定時時間（分）
RET
BMQCL18:
MOV A,#30 ;“分”小于30，把30放入寄存器A
CLR C ;進位標志清0
SUBB A,DSSJF ;減“定時時間（分）”
MOV DSSJF,A ;減完后的結(jié)果暫時放入DSSJF
MOV A,#60
SUBB A,DSSJF ;60減上面的計算結(jié)果，得出定時時間（分），然后小時減1
MOV DSSJF,A ;得出的數(shù)放入定時時間（分）
MOV A,DSSJS ;裝入定時時間（時）
JZ DSSJQL ;如果“時”為0就轉(zhuǎn)移（不夠減了，把定時時間清零）
DEC DSSJS ;“時”不為0，減1
RET
DSSJQL:
MOV DSSJS,#0 ;定時時間清零
MOV DSSJF,#0 ;定時時間清零
MOV DSSJM,#0 ;定時時間清零
RET
;----------------------------------------------------------------------------------------------
;子程序：掃描編碼器是否有旋轉(zhuǎn)動作并設置好方向標志
;出口參數(shù)：“編碼器動作”=1已經(jīng)轉(zhuǎn)動，=0沒有轉(zhuǎn)動；“旋轉(zhuǎn)方向”=1順時針正轉(zhuǎn)，=0逆時針反轉(zhuǎn)
;----------------------------------------------------------------------------------------------
Scan1:
SETB EC11A ;拉高編碼器A引腳電平
SETB EC11B ;拉高編碼器B引腳電平
JNB EC11A,Scan11 ;如果為0(低電平)就轉(zhuǎn)移，編碼器有旋轉(zhuǎn)動作，順時針正轉(zhuǎn)
JNB EC11B,Scan12 ;如果為0(低電平)就轉(zhuǎn)移，編碼器有旋轉(zhuǎn)動作，逆時針反轉(zhuǎn)
CLR BMQDZ ;沒有旋轉(zhuǎn)動作，把“編碼器動作”置為0
RET
Scan11:
SETB XZFX ;順時針正轉(zhuǎn)，把“旋轉(zhuǎn)方向”置為1
SETB BMQDZ ;有旋轉(zhuǎn)動作，把“編碼器動作”置為1
LCALL SETPWM ;有動作就重新放置“延時PWM驅(qū)動”時間
RET
Scan12:
CLR XZFX ;逆時針反轉(zhuǎn)，把“旋轉(zhuǎn)方向”置為0
SETB BMQDZ ;有旋轉(zhuǎn)動作，把“編碼器動作”置為1
LCALL SETPWM ;有動作就重新放置“延時PWM驅(qū)動”時間
RET
;-------------------------------------------------------------
;子程序：掃描編碼器是否有旋轉(zhuǎn)動作，不設置方向標志
;出口參數(shù)：“編碼器動作”BMQDZ=1已經(jīng)轉(zhuǎn)動，=0沒有轉(zhuǎn)動
;-------------------------------------------------------------
Scan2:
SETB EC11A ;拉高編碼器A引腳電平
SETB EC11B ;拉高編碼器B引腳電平
JNB EC11A,Scan21 ;如果為0(低電平)就轉(zhuǎn)移，編碼器有旋轉(zhuǎn)動作
JNB EC11B,Scan21 ;如果為0(低電平)就轉(zhuǎn)移，編碼器有旋轉(zhuǎn)動作
CLR BMQDZ ;沒有旋轉(zhuǎn)動作，把“編碼器動作”置為0
RET
Scan21:
SETB BMQDZ ;有旋轉(zhuǎn)動作，把“編碼器動作”置為1
LCALL SETPWM ;有動作就重新放置“延時PWM驅(qū)動”時間
RET
;--------------------------------------------------------------
;子程序：繼電器控制，T0中斷、EEPROM操作子程序調(diào)用
;--------------------------------------------------------------
Control:
JNB EEPBC,CTL00 ;EEPBC標志為0就轉(zhuǎn)移。為1表示EEPROM操作子程序正在調(diào)用下面的繼電器控制程序
RET
CTL00:
MOV A,DSSJM ;裝入定時時間(秒)到寄存器A
JNZ CTL02 ;不是0就轉(zhuǎn)移
MOV A,DSSJF ;裝入定時時間(分)到寄存器A
JNZ CTL02 ;不是0就轉(zhuǎn)移
MOV A,DSSJS ;裝入定時時間(時)到寄存器A
JNZ CTL02 ;不是0就轉(zhuǎn)移
CTL01:
MOV P3,#0FFH ;置P3端口為高電平，斷電
RET
CTL02:
JNB PWM,CTL03 ;PWM標志為0就轉(zhuǎn)移。0=禁止PWM驅(qū)動，1=使用PWM方式驅(qū)動
MOV A,YSPWM ;裝入“延時PWM驅(qū)動”，為0時使用PWM驅(qū)動方式
JNZ CTL03 ;不是0就轉(zhuǎn)移
JB PWMBZ,CTL01 ;“PWM電平狀態(tài)標志”為1(高電平)就轉(zhuǎn)移。PWM周期25微秒*2=50微秒，20KHz占空比50%
CTL03:
JB FLQH,CTL05 ;“風類切換”為1自然風(睡眠風)就轉(zhuǎn)移
MOV A,DANG ;裝入檔位值
CTL04:
PUSH DPL
PUSH DPH
MOV DPTR,#DAB1 ;檔位控制碼地址
DEC A ;檔位值減1后為正確地址
MOVC A,@A+DPTR ;裝入檔位控制碼
MOV P3,A ;置P3口控制繼電器
POP DPH
POP DPL
RET
CTL05:
MOV A,SMFJG2 ;裝入自然風(睡眠風)檔位變化時的間隔時間(秒)
JZ CTL06 ;是0就轉(zhuǎn)移
MOV A,DANGW ;裝入自然風當前檔位
LJMP CTL04
CTL06:
MOV SMFJG2,SMFJG ;重新放入設置的檔位變化間隔時間
LCALL SETPWM ;設置“延時PWM驅(qū)動”時間
MOV A,DANGW ;裝入當前檔位值
JNB TSFX,CTL09 ;如果“調(diào)速方向”為0（漸慢降檔）就轉(zhuǎn)移
CJNE A,DANG_G,CTL07 ;當前檔位值是否等于或大于設置的最高上限
CTL07:
JC CTL08 ;小于就轉(zhuǎn)移
MOV A,DANG_G ;等于或大于，裝入最高上限
CLR TSFX ;“調(diào)速方向”改為0（漸慢降檔）
LJMP CTL09
CTL08:
INC A ;增1檔
MOV DANGW,A
LJMP CTL04
CTL09:
CJNE A,DANG_D,CTL10 ;當前檔位值不是設置的最低下限就轉(zhuǎn)移
SETB TSFX ;是，“調(diào)速方向”改為1（漸快增檔）
LJMP CTL04
CTL10:
JC CTL13 ;小于就轉(zhuǎn)移
CJNE A,DANG_G,CTL11 ;是否大于設置的最高上限
CTL11:
JC CTL12 ;小于就轉(zhuǎn)移
MOV A,DANG_G ;等于或大于，裝入最高上限
CTL12:
DEC A ;減1檔
MOV DANGW,A
LJMP CTL04
CTL13:
MOV A,DANG_D ;小于最低下限，裝入最低下限
MOV DANGW,A
LJMP CTL04
;--------------------------------------------------------------
;子程序：T1中斷調(diào)用，時間計數(shù)及倒計時處理。10毫秒執(zhí)行一次
;--------------------------------------------------------------
TIME:
MOV A,YSPWM ;延時PWM驅(qū)動
JZ TIME0
DEC YSPWM ;每10毫秒減1，直到為0
TIME0:
MOV A,FENGMQ ;蜂鳴器鳴響時長
JZ TIME1
DEC FENGMQ ;每10毫秒減1，直到為0
TIME1:
MOV A,SHMJS ;裝入(10)毫秒計數(shù)
JZ TIME2 ;如果是0就轉(zhuǎn)移
DEC SHMJS ;每10毫秒減1，直到為0
TIME2:
MOV A,HWJS ;每10毫秒減1，為0時清除“接收到的紅外遙控數(shù)據(jù)碼”
JZ TIME3 ;是0就轉(zhuǎn)移
DEC HWJS ;減1
LJMP TIME4
TIME3:
MOV MA1,FWBZ1 ;用“復位及EEPROM判斷標志”填充“接收到的紅外遙控數(shù)據(jù)碼”
MOV MA2,FWBZ2 ;用“復位及EEPROM判斷標志”填充“接收到的紅外遙控數(shù)據(jù)碼”
TIME4:
MOV A,HMJS ;裝入(10)毫秒計數(shù)2
JZ TIME6 ;如果是0就轉(zhuǎn)移
DEC HMJS ;不是0，減1
CJNE A,#50,TIME5 ;如果不是50就轉(zhuǎn)移退出
SETB SSBZ ;“閃爍標志”置為1，數(shù)字及冒號閃爍時用，每0.5秒變化一次
TIME5:
RET
TIME6:
CLR SSBZ ;“閃爍標志”置為0，數(shù)字及冒號閃爍時用，每0.5秒變化一次
MOV HMJS,#99 ;重新放入計數(shù)值（1秒）
MOV A,SMFJG2 ;裝入運行時使用的“睡眠風(自然風)檔位變化時的間隔時間(秒)”
JZ TIME7 ;如果是0就轉(zhuǎn)移
DEC SMFJG2 ;每秒減1，直到為0
TIME7:
MOV A,MJS ;秒計數(shù)
JZ TIME8 ;如果是0就轉(zhuǎn)移
DEC MJS ;每秒減1，直到為0
TIME8:
MOV A,FWBZ0 ;裝入復位提示(閃爍顯示)秒計數(shù)
JZ TIME9 ;如果是0就轉(zhuǎn)移
DEC FWBZ0 ;每秒減1，直到為0
TIME9:
MOV A,DSDW ;裝入定時與檔位交替顯示的間隔時間(秒)
JNZ TIME10 ;如果不是0就轉(zhuǎn)移
MOV DSDW,DSDWJG ;重新放入設置值
CPL XSNRXZ ;“顯示內(nèi)容選擇”取反，交替顯示
TIME10:
DEC DSDW ;每秒減1，直到為0
MOV A,DSSJM ;裝入定時時間(秒)到寄存器A
JZ TIME11 ;如果是0就轉(zhuǎn)移
DEC DSSJM ;減1秒
RET
TIME11:
MOV A,DSSJF ;裝入定時時間(分)到寄存器A
JZ TIME12 ;如果是0就轉(zhuǎn)移
DEC DSSJF ;不是0，減1分
MOV DSSJM,#59 ;把59放入定時時間(秒)
RET
TIME12:
MOV A,DSSJS ;裝入定時時間(時)到寄存器A
JNZ TIME13 ;不是0就轉(zhuǎn)移
CLR XSNRXZ ;定時結(jié)束，“顯示內(nèi)容選擇”置為0，不顯示檔位
RET
TIME13:
DEC DSSJS ;不是0，小時減1
MOV DSSJM,#59 ;把59放入定時時間(秒)
MOV DSSJF,#59 ;把59放入定時時間(分)
RET
;---------------------------------------------------------------------------
;子程序：T1中斷調(diào)用，顯示定時時間及檔位、紅外遙控解碼等。10毫秒執(zhí)行一次
;---------------------------------------------------------------------------
DISPLAY:
JB XSKG,DPYSZ1 ;如果“顯示開關”為1(禁止T1顯示功能)就轉(zhuǎn)移，退出
JNB XSQHY,DPYSZ0 ;如果“顯示切換1”為0(顯示定時或檔位)就轉(zhuǎn)移
LJMP DSZ
DPYSZ0:
JB FLQH,DISPL0 ;如果“風類切換”為1睡眠風(自然風)就轉(zhuǎn)移，顯示定時時間
JNB XSNRXZ,DISPL0 ;如果“顯示內(nèi)容選擇”為0(顯示定時時間)就轉(zhuǎn)移
MOV A,DANG ;顯示檔位，裝入檔位值
CJNE A,XSHC1,DPYSZ3 ;當前檔位值與緩存1不相同就轉(zhuǎn)移，立即顯示
MOV A,HMJS ;相同，裝入(10)毫秒計數(shù)2
CJNE A,#99,DPYSZ2 ;不是99就轉(zhuǎn)移，每0.5秒顯示一次
LJMP DPYSZ3 ;是，顯示
DPYSZ1: RET
DPYSZ2:
CJNE A,#49,DPYSZ1 ;不是49就轉(zhuǎn)移退出，每0.5秒顯示一次
DPYSZ3:
MOV XSHC1,DANG ;當前檔位值放入緩存1
MOV ZXM1,#0 ;放入消隱碼到待發(fā)送TM1637區(qū)1
MOV ZXM4,#0 ;放入消隱碼到待發(fā)送TM1637區(qū)4
MOV R0,#ZXM2 ;裝入待發(fā)送TM1637區(qū)2地址
MOV A,DANG ;裝入檔位值
LCALL BCD ;轉(zhuǎn)換并獲取字形碼放到待發(fā)送TM1637區(qū)2和3
LCALL disp ;發(fā)送4個字節(jié)數(shù)據(jù)到TM1637顯示
RET
;--------------------------------
DISPL0:
CLR XSNRXZ ;“顯示內(nèi)容選擇”置為0，顯示定時時間
MOV R1,#DSSJS ;把定時時間“時”的地址放入R1
MOV A,@R1 ;裝入“時”
JZ DISPL1 ;如果“時”為0就轉(zhuǎn)移
LJMP DISPL3
DISPL1:
CLR SSBZ ;“時”為0，把“閃爍標志”置為0，始終顯示冒號
INC R1 ;地址加1，指向“分”
MOV A,@R1 ;裝入“分”
DISPL3:
CJNE A,XSHC1,DISPL6 ;寄存器A的數(shù)據(jù)與顯示緩存1不相同就轉(zhuǎn)移，立即顯示
INC R1 ;地址加1
MOV A,@R1 ;裝入下一個時間數(shù)值
DEC R1 ;地址減1
CJNE A,XSHC2,DISPL6 ;寄存器A的數(shù)據(jù)與顯示緩存2不相同就轉(zhuǎn)移，立即顯示
MOV A,HMJS ;都相同，裝入(10)毫秒時間計數(shù)2
CJNE A,#99,DISPL5 ;不是99就轉(zhuǎn)移
LJMP DISPL6 ;是，顯示（每0.5秒顯示一次）
DISPL4: RET
DISPL5:
CJNE A,#49,DISPL4 ;不是49就轉(zhuǎn)移退出，每0.5秒顯示一次
DISPL6:
INC R1 ;地址加1
MOV A,@R1 ;裝入后面一位時間數(shù)值
MOV XSHC2,A ;放入緩存2
DEC R1 ;地址減1
MOV A,@R1 ;裝入前面一位時間數(shù)值
MOV XSHC1,A ;放入緩存1
MOV R0,#ZXM1 ;待發(fā)送TM1637區(qū)1地址
LCALL BCD ;轉(zhuǎn)換并獲取字形碼放到待發(fā)送TM1637區(qū)1、2
INC R1 ;地址加1
MOV R0,#ZXM3 ;待發(fā)送TM1637區(qū)3地址
MOV A,@R1 ;裝入后面一位時間數(shù)值
LCALL BCD ;轉(zhuǎn)換并獲取字形碼放到待發(fā)送TM1637區(qū)3、4
JB SSBZ,DISPL8 ;如果“閃爍標志”為1就轉(zhuǎn)移，不顯示冒號
DISPL7:
ORL ZXM2,#10000000B ;把最高位置為1（最高位為1就顯示冒號）
DISPL8:
LCALL disp ;發(fā)送4個字節(jié)數(shù)據(jù)到TM1637顯示
RET
;--------------------------------
DSZ:
JNB XSQHE,DHW ;如果“顯示切換2”為0(顯示紅外遙控信號解碼)就轉(zhuǎn)移
MOV A,ZRFJG ;裝入當前要顯示的項目號，1:檔位下限；2=檔位上限；3=檔位變化的間隔時間(秒)
DEC A ;減1
JNZ DSZ1 ;不為0就轉(zhuǎn)移
MOV A,DANG_D ;是1，顯示檔位下限
MOV ZXM1,#038H ;放入“L”到待發(fā)送TM1637區(qū)1
LJMP DSZ3
DSZ1:
DEC A ;減1
JNZ DSZ2 ;不為0就轉(zhuǎn)移
MOV A,DANG_G ;是2，顯示檔位上限
MOV ZXM1,#076H ;放入“H”到待發(fā)送TM1637區(qū)1
LJMP DSZ3
DSZ2:
MOV A,SMFJG ;是3，顯示檔位變化的間隔時間(秒)
MOV ZXM1,#079H ;放入“E”到待發(fā)送TM1637區(qū)1
DSZ3:
MOV ZXM2,#040H ;放入“-”到待發(fā)送TM1637區(qū)2
MOV R0,#ZXM3 ;待發(fā)送TM1637區(qū)3地址
LCALL BCD ;轉(zhuǎn)換并獲取字形碼放到待發(fā)送TM1637區(qū)2和3
LCALL disp ;顯示
RET
;---------------------------------
DHW:
JB BMXSQH,DHW4 ;如果“編碼顯示切換”為1(顯示數(shù)據(jù)碼+反碼)就轉(zhuǎn)移
MOV A,XMBH ;裝入功能編號
CJNE A,XSHC1,DHW3 ;與顯示緩存1不相同就轉(zhuǎn)移，立即顯示
MOV A,HMJS ;相同，裝入(10)毫秒計數(shù)
CJNE A,#99,DHW2 ;不是99就轉(zhuǎn)移，每0.5秒顯示一次
LJMP DHW3 ;是，顯示
DHW1: RET
DHW2:
CJNE A,#49,DHW1 ;不是49就轉(zhuǎn)移退出，每0.5秒顯示一次
DHW3:
MOV XSHC1,XMBH ;功能編號放入緩存1
MOV R0,#ZXM1 ;顯示功能編號+系統(tǒng)碼，待發(fā)送TM1637區(qū)1
MOV A,XMBH ;裝入功能編號
LCALL BCD1 ;獲取字形碼放到待發(fā)送TM1637區(qū)
MOV ZXM2,#040H ;放入“-”到待發(fā)送TM1637區(qū)2
MOV A,ANJZ ;裝入系統(tǒng)碼
MOV R0,#ZXM3 ;待發(fā)送TM1637區(qū)3
LCALL HEX ;顯示十六進制系統(tǒng)碼
LCALL disp ;顯示十六進制系統(tǒng)碼
RET
DHW4:
MOV A,XMBH ;裝入功能編號
MOV B,#2 ;功能編號乘2
MUL AB ;功能編號乘2
DEC A ;計算結(jié)果減1
ADD A,#ANJZ ;加遙控按鍵值首地址，得出數(shù)據(jù)碼的實際地址
MOV R1,A ;地址放入R1
MOV A,@R1 ;裝入數(shù)據(jù)碼
CJNE A,XSHC1,DHW7 ;與顯示緩存1不相同就轉(zhuǎn)移，立即顯示
INC R1 ;地址加1
MOV A,@R1 ;裝入裝入數(shù)據(jù)碼反碼
DEC R1 ;地址減1
CJNE A,XSHC2,DHW7 ;與顯示緩存2不相同就轉(zhuǎn)移，立即顯示
MOV A,HMJS ;都相同，裝入(10)毫秒時間計數(shù)
CJNE A,#99,DHW6 ;不是99就轉(zhuǎn)移
LJMP DHW7 ;是，顯示（每0.5秒顯示一次）
DHW5: RET
DHW6:
CJNE A,#49,DHW5 ;不是49就轉(zhuǎn)移退出，每0.5秒顯示一次
DHW7:
INC R1 ;地址加1
MOV A,@R1 ;裝入數(shù)據(jù)碼反碼
MOV XSHC2,A ;放入緩存2
DEC R1 ;地址減1
MOV A,@R1 ;裝入數(shù)據(jù)碼碼
MOV XSHC1,A ;放入緩存1
MOV R0,#ZXM1 ;待發(fā)送TM1637區(qū)1
LCALL HEX ;查表獲取字形碼
MOV A,@R1 ;裝入數(shù)據(jù)碼反碼
LCALL HEX ;查表獲取字形碼
LCALL disp ;顯示
RET
;---------------------------------
HEX:
PUSH ACC
SWAP A ;高低半字節(jié)交換
ANL A,#0FH ;邏輯與運算
LCALL BCD1 ;查表獲取字形碼放到待發(fā)送TM1637區(qū)
INC R0 ;地址加1
POP ACC
ANL A,#0FH ;邏輯與運算
LCALL BCD1 ;查表獲取字形碼放到待發(fā)送TM1637區(qū)
INC R0 ;地址加1
INC R1 ;地址加1
RET
;---------------------------------
BCD:
MOV B,#10 ;轉(zhuǎn)換為BCD碼
DIV AB ;轉(zhuǎn)換為BCD碼
PUSH DPL
PUSH DPH
MOV DPTR,#SEGTAB ;查表獲取字形碼
MOVC A,@A+DPTR ;查表獲取字形碼
POP DPH
POP DPL
MOV @R0,A ;字形碼放入待發(fā)送TM1637區(qū)
INC R0 ;地址加1
XCH A,B ;A、B寄存器內(nèi)容交換
BCD1:
PUSH DPL
PUSH DPH
MOV DPTR,#SEGTAB ;查表獲取字形碼
MOVC A,@A+DPTR ;查表獲取字形碼
POP DPH
POP DPL
MOV @R0,A ;字形碼放入待發(fā)送TM1637區(qū)
RET
;************** 關閉T1中斷的顯示功能，顯示“----”**************
HENGX:
SETB XSKG ;“顯示開關”置為1，關閉T1中斷的顯示功能
MOV ZXM1,#40H ;顯示“----”
MOV ZXM2,#40H
MOV ZXM3,#40H ;顯示“----”
MOV ZXM4,#40H
LJMP disp0
;---------- 發(fā)送4個字節(jié)數(shù)據(jù)到TM1637顯示，地址自動加1 ----------
disp:
MOV A,FWBZ0 ;裝入復位提示(閃爍顯示)秒計數(shù)
JZ disp0 ;如果是0(未發(fā)生復位)就轉(zhuǎn)移
JNB SSBZ,disp0 ;已經(jīng)發(fā)生復位，“閃爍標志”為0(閃爍顯示中的“顯示”狀態(tài))就轉(zhuǎn)移
CLR A ;處于閃爍顯示中的“不顯示”狀態(tài)，放入消隱碼（0）
MOV ZXM1,A ;放入消隱碼
MOV ZXM2,A ;放入消隱碼
MOV ZXM3,A ;放入消隱碼
MOV ZXM4,A ;放入消隱碼
disp0:
LCALL Srt
MOV A,#040H ;數(shù)據(jù)命令設置40H：地址自動加1，寫數(shù)據(jù)到顯示寄存器
LCALL Writebyte ;發(fā)送一個字節(jié)
LCALL Stop
NOP
LCALL Srt
MOV A,#0C0H ;地址命令設置C0H：初始地址為00H
LCALL Writebyte ;發(fā)送一個字節(jié)
MOV R6,#4 ;發(fā)送4個字節(jié)數(shù)據(jù)
MOV R1,#ZXM1 ;等待發(fā)送的字形碼始址
disp1:
MOV A,@R1 ;裝入要發(fā)送的字形碼
LCALL Writebyte ;發(fā)送一個字節(jié)
INC R1 ;地址加1
DJNZ R6,disp1 ;如果還未發(fā)送完就繼續(xù)
LCALL Stop
LCALL Srt
MOV A,SMGLD ;裝入設置的數(shù)碼管亮度(1~8)
ADD A,#087H ;加上87H后即為對應的亮度控制命令88H~8FH
LCALL Writebyte ;按設置的亮度開顯示
LCALL Stop
RET
;----- 發(fā)送8bit(一個字節(jié))數(shù)據(jù)到TM1637，A=要發(fā)送的數(shù)據(jù)，從低位開始 -----
Writebyte:
MOV R7,#8 ;發(fā)送8位數(shù)據(jù)
WBY1:
CLR CLK ;拉低CLK
JNB ACC.0,WBY2 ;A寄存器的低位（0位）如果為0就轉(zhuǎn)移
SETB DIO ;為1，拉高DIO
SJMP WBY3
WBY2:
CLR DIO ;為0，拉低DIO
WBY3:
MOV R4,#13 ;延時
DJNZ R4,$ ;延時
SETB CLK ;拉高CLK
CLR C ;進位標志清0
RRC A ;A寄存器內(nèi)容帶進位循環(huán)右移
DJNZ R7,WBY1 ;如果還未發(fā)送完8bit數(shù)據(jù)就繼續(xù)
CLR CLK ;8位數(shù)據(jù)發(fā)送完了
MOV R7,#20 ;設置等待應答信號延時計數(shù)
WBY5:
JNB DIO,WBY6 ;判斷TM1637發(fā)過來的ACK應答信號，應答就轉(zhuǎn)移(0，低電平)
DJNZ R7,WBY5 ;
WBY6:
MOV R4,#13 ;延時
DJNZ R4,$ ;延時
SETB CLK ;拉高CLK
MOV R4,#13 ;延時
DJNZ R4,$ ;延時
RET
;------------------ Start子程序 ------------------
Srt:
SETB DIO ;拉高DIO
SETB CLK ;拉高CLK
MOV R4,#13 ;延時
DJNZ R4,$ ;延時
SETB DIO ;拉高DIO
MOV R4,#13 ;延時
DJNZ R4,$ ;延時
CLR DIO ;拉低DIO
MOV R4,#13 ;延時
DJNZ R4,$ ;延時
CLR CLK ;拉低CLK
RET
;------------------ Stop子程序 ------------------
Stop:
CLR CLK
MOV R4,#30
DJNZ R4,$
CLR DIO
MOV R4,#30
DJNZ R4,$
SETB CLK
MOV R4,#40
DJNZ R4,$
SETB DIO
MOV R4,#30
DJNZ R4,$
CLR CLK
CLR DIO
RET
;********************** 以下為EEPROM操作子程序 **********************
;STC8G1K08有4K的EEPROM，共8個扇區(qū)，
;第1扇區(qū)：0000H~01FFH；第2扇區(qū)：0200H~03FFH……
;----------------------------------------------------
;
;------- 讀EEPROM保存的各項設置，如果沒有就保存當前的設置值 ---------
REEP:
LCALL RE00 ;讀EEPROM
JNC WEEP ;無數(shù)據(jù)(C=0)就轉(zhuǎn)移，保存當前的設置值
RET
WEEP:
LCALL BCJDQ ;全功率驅(qū)動繼電器保持至EEPROM操作結(jié)束，防止PWM驅(qū)動方式時可能斷開無法吸合
MOV IAP_ADDRH,#00H ;第一個扇區(qū)地址的高8位
MOV IAP_ADDRL,#00H ;第一個扇區(qū)地址的低8位
LCALL Sector_Erase ;擦除整個扇區(qū)
MOV R1,#FWBZ1 ;首地址
MOV R2,#30 ;共寫入20個字節(jié)
WEEP1:
MOV A,@R1 ;裝入R1指向的RAM地址的內(nèi)容到A
LCALL Byte_Program ;寫入EEPROM
INC IAP_ADDRL ;EEPROM地址加1
INC R1 ;RAM地址增1
DJNZ R2,WEEP1 ;未保存完就轉(zhuǎn)移繼續(xù)
MOV IAP_ADDRL,#0 ;保存完了，扇區(qū)地址低位指向0(當前扇區(qū)首址)
LCALL Byte_Read ;讀出來檢查看是否寫入成功
CJNE A,FWBZ1,WEEP3 ;如果與EEPROM數(shù)據(jù)判斷標志1不相同就轉(zhuǎn)移
INC IAP_ADDRL ;EEPROM地址加1
LCALL Byte_Read ;讀第二個字節(jié)
CJNE A,FWBZ2,WEEP3 ;如果與EEPROM數(shù)據(jù)判斷標志2不相同就轉(zhuǎn)移
RET ;成功了，退出
WEEP3:
SETB XSKG ;“顯示開關”置為1，關閉T1中斷的顯示功能
MOV MJS,#5 ;顯示5秒E1
MOV ZXM1,#0 ;消隱碼
MOV ZXM2,#079H ;E
MOV ZXM3,#006H ;1
MOV ZXM4,#0 ;消隱碼
LCALL DISP ;顯示
WEEP4:
MOV A,MJS
JNZ WEEP4 ;等待MJS為0秒
RET
;;---------- 讀EEPROM保存的各項設置 ----------
RE00:
LCALL BCJDQ ;全功率驅(qū)動繼電器保持至EEPROM操作結(jié)束，防止PWM驅(qū)動方式時可能斷開無法吸合
MOV IAP_ADDRH,#00H ;第一個扇區(qū)地址的高8位
MOV IAP_ADDRL,#00H ;第一個扇區(qū)地址的低8位
LCALL Byte_Read ;讀第一個字節(jié)，返回：A=讀出的數(shù)據(jù)
CJNE A,FWBZ1,RE02 ;如果不是原來保存的數(shù)據(jù)就轉(zhuǎn)移
INC IAP_ADDRL ;EEPROM字節(jié)地址增1
LCALL Byte_Read ;讀第二個字節(jié)
CJNE A,FWBZ2,RE02 ;如果不是原來保存的數(shù)據(jù)就轉(zhuǎn)移
MOV R1,#FWBZ2 ;從FWBZ2+1處開始放置讀出的設置值
MOV R2,#28 ;再讀出28個字節(jié)
RE01:
INC R1 ;RAM地址增1
INC IAP_ADDRL ;EEPROM字節(jié)地址增1
LCALL Byte_Read ;讀一個字節(jié)，返回：A=讀出的數(shù)據(jù)
MOV @R1,A ;放到R1指向的RAM地址
DJNZ R2,RE01 ;未讀完就繼續(xù)
SETB C ;把C置為1，讀取成功
RET
RE02:
CLR C ;把C置為0，沒有數(shù)據(jù)
RET
;-------------------------------
;EEPROM操作需要數(shù)毫秒以上，期間MCU會暫停，PWM停止。
;全功率驅(qū)動使繼電器保持吸合狀態(tài)至EEPROM操作結(jié)束，防止PWM驅(qū)動方式時可能斷開無法吸合
BCJDQ:
LCALL SETPWM ;設置“延時PWM驅(qū)動”時間
SETB EEPBC ;“EEPROM操作子程序調(diào)用”標志置為1，使T0中斷暫停執(zhí)行繼電器控制程序
LCALL CTL00 ;控制繼電器
CLR EEPBC ;標志置為0
RET
;-------------------------------
;讀一個字節(jié)，A=讀出的數(shù)據(jù)
Byte_Read:
MOV IAP_CONTR,#80H ;打開IAP功能
MOV IAP_TPS,#12 ;設置等待參數(shù)
MOV IAP_CMD,#01 ;設置IAP讀命令
MOV IAP_TRIG,#05AH ;觸發(fā)命令
MOV IAP_TRIG,#0A5H ;觸發(fā)命令
NOP
MOV A,IAP_DATA ;讀出的數(shù)據(jù)在IAP_DATA，送入累加器A
RET
;-------------------------------
;字節(jié)編程，A=需寫入的數(shù)據(jù)
Byte_Program:
MOV IAP_CONTR,#80H ;打開IAP功能
MOV IAP_TPS,#12 ;設置等待參數(shù)
MOV IAP_CMD,#02 ;設置IAP寫命令
MOV IAP_DATA,A ;要寫入的數(shù)據(jù)先送進IAP_DATA寄存器
MOV IAP_TRIG,#05AH ;觸發(fā)命令
MOV IAP_TRIG,#0A5H ;觸發(fā)命令
RET
;-------------------------------
;擦除扇區(qū)
Sector_Erase:
MOV IAP_CONTR,#80H ;打開IAP功能
MOV IAP_TPS,#12 ;設置等待參數(shù)
MOV IAP_CMD,#03 ;設置IAP擦除命令
MOV IAP_TRIG,#05AH ;觸發(fā)命令
MOV IAP_TRIG,#0A5H ;觸發(fā)命令
RET
;************************* 以上為EEPROM操作子程序 ***************************
;
;1~15檔控制碼：
DAB1: DB 0FEH,0FDH,0FBH,0FAH,0F9H,0F8H,0F4H,0F2H,0F1H,0F0H,0E4H,0E2H,0E1H,0E0H,0DFH
;
;------------------ 字形表 ------------------
SEGTAB:
DB 00111111B ;0（3FH）
DB 00000110B ;1（06H）
DB 01011011B ;2（5BH）
DB 01001111B ;3（4FH）
DB 01100110B ;4（66H）
DB 01101101B ;5（6DH）
DB 01111101B ;6（7DH）
DB 00000111B ;7（07H）
DB 01111111B ;8（7FH）
DB 01101111B ;9（6FH）
DB 01110111B ;A（77H）
DB 01111100B ;B（7CH）
DB 00111001B ;C（39H）
DB 01011110B ;D（5EH）
DB 01111001B ;E（79H）
DB 01110001B ;F（71H）
;---------------------------------------------
END

復制代碼

久久久久久久999_99精品久久精品一区二区爱城_成人欧美一区二区三区在线播放_国产精品日本一区二区不卡视频_国产午夜视频_欧美精品在线观看免费