今天又解決了一項難題，這是一個用INT0接收MIDI串行碼的程序，想法是這樣的，開啟INT0等候MIDI訊號，當起始BIT到來時，關(guān)閉INT0，寫個定時時間為16US（一個MIDI BIT是32US）的值（TML—SHORT）入T0， 開啟T0中斷，開動T0，預計會在一個BIT的中點產(chǎn)生中斷，接下來就寫入定時時間為32us的值（TML）入T0，這樣就能連續(xù)讀到每個BIT中點的值，直到讀完8個BIT，最后一個是停止BIT，無所謂，把讀到的1byte寫入緩沖就完成一對一個MIDI訊號的讀取，實驗結(jié)果是可行的，但是好好的鍵盤彈著彈著就會出現(xiàn)怪音，亂碼。當然就開始懷疑硬件出問題了，連最名牌的音源發(fā)生器也懷疑是否有BUG，今天終于想出個辦法，就是用邏輯分析儀觀測輸入的MIDI訊號，在軟件內(nèi)部加入setb p2.0, cpl p2.0 的命令，比較二者的時序，這才發(fā)現(xiàn)原來INT0 并非想象訊號來的時候馬上就觸發(fā)，而會延時6-7US（3.6M晶振），加上16US就是23US，已經(jīng)接近一個BIT的尾端，若偶爾BIT有些延時就會讀到BIT外的數(shù)值了，這就是亂碼的由來，把16US 減為10US后，哈！神助啊，亂彈一萬個鍵也不會錯了，高興之余，就把這波形和原碼上載分享，慶祝一條大蟲伏誅了。
但還在納悶為何這名牌鍵盤產(chǎn)生的MIDI碼也是時長時短的，沒有規(guī)則，不可能吧？又懷疑是用廉價的24M邏輯分析儀了，但問題也算解決了，單片機的INT0是會有延時的，記住了。
49k-a.jpg (55.15 KB, 下載次數(shù): 45)
下載附件
2018-12-5 23:28 上傳
49k-b.jpg (56.23 KB, 下載次數(shù): 36)
下載附件
2018-12-5 23:28 上傳
單片機匯編語言源程序如下：
EXT_INT0: ;IF P3.2 H2L COME HERE SET TIMER, ONLY FIRST H2L WILL ACT
SETB P2.0
CLR EX0 ;STOP THE INTERRUPT_O
MOV TH0,#TMH ;load value to T0 high 8 bits a value
MOV TL0,#TML_SHORT ;load half value to T0 low 8 bits a value
;SETB PT0 ;set T0 interupt parity HIGH
SETB ET0 ;switch on T0 interrupt
SETB TR0 ;SWITCH ON T0 to run
;NOP
MOV R6,#8 ;9 BIT TO CHECK
RETI
TIMER_0: ;CHECK INPUT MIDI SIGNAL AT P3.2
CPL P2.0
PUSH ACC
JB 11H, STOPREADBIT
JB 10H, STARTREADBIT
SETB 10H
MOV R5, #00000000B ;FIRST BIT
NOP
NOP
NOP
NOP
NOP
NOP
NOP
NOP
NOP
NOP
JMP NEXTBIT
STARTREADBIT:
MOV A, P3 ;READ FROM PORT3
ANL A, #00000100B ;MASKING ALL EXCEPT P3.2 BIT
JNZ SETTOHIGH
CLR C
JMP CLOCKIN
SETTOHIGH:
SETB C
CLOCKIN:
MOV A, R5
RRC A
MOV R5, A
DEC R6
MOV A, R6
JNZ NEXTBIT
SETB 11H ;STOP BIT
JMP NEXTBIT
STOPREADBIT:
CLR 10H
CLR 11H
MOV A, R5 ;LOAD A WITH RECEIVED DATA BYTE
MOV @R1, A ;SAVE TO BUFFER
CLR TR0 ;STOP THE TIMER_0
SETB PX0 ;SET EXTERNAL INTERRUT PARITY TO HIGH
CLR IE0 ;CLEAR EXTERNAL INTERRUT FLAG
SETB IT0 ;SET AS H TO L AS INTERRUT METHOD
SETB EX0 ;REOPEN EXTERNAL INTERRUPT 0
CJNE R1, #LASTBUFFER, NEXTREADBUFFER
MOV R1, #FIRSTBUFFER
JMP NEXTBIT1
NEXTREADBUFFER:
INC R1 ;POINT TO NEXT BUFFER
CLR P2.0
JMP NEXTBIT1
NEXTBIT:
NOP
NOP
NOP
NOP
NOP
NOP
MOV TH0,#TMH ;load value to T0 high 8 bits a value
MOV TL0,#TML ;load value to T0 low 8 bits a value
NEXTBIT1:
POP ACC
RETI
EXT_INT1: ;USE FOR INFRA RED
CLR EX0 ;STOP MIDI
CLR EX1 ;STOP THE INTERRUPT_1
LCALL INFRARED
RETI
|
QQ好友和群
QQ空間
騰訊微博
騰訊朋友
收藏
淘帖
頂
踩
