首先說一下 想寫這個帖子 看到論壇上有關于遙控器方面的帖子 但是都沒有很詳細的介紹 而且是已經有完整的波形 僅僅介紹了解碼部分 而沒有分析波形數據方面的介紹 ，因此有了寫一篇完整的關于遙控器方面的文章的沖動 此貼對新手可能有點困難不過 不要緊 我會以最通俗的方式來解釋 如果有不明白的 建議去看看書 ，自己努力 沒有不可能的事 別人能做到 你也一定行，關于紅外遙控的基礎理論，大家可以到這個貼去看下http://www.zg4o1577.cn/mcu/184.html，里面有詳細的介紹。在這里我僅把一些關鍵的帶出來 關于硬件電路 那么拋開那么多文字介紹 最后意思就是說 你家里的遙控板 也就是發射部分 是把所有的封裝好了的 比如鍵盤矩陣、編碼調制、LED紅外發送器 等等 那么接受部分 SM0038 3個腳 一個腳地 一個腳電源 一個腳信號腳 接到 單片機隨便個P口上（此處是P3。6） OK 硬件部分就搞定了當然還有數碼管顯示 ，這些肯定不用說你都能搞定吧，我這剛好有一塊51hei單片機學習板是在www.zg4o1577.cn的論壇買的，這些東東都有,所以就不用自己去搭電路那么麻煩了），那么 我們想 我們按一下遙控板 大家看到 有個燈閃了一下 然后OVER 那么 我們現在要做的就是在燈閃了那一下之后讓 單片機來讀它的鍵碼 然后不同的鍵碼來干不同的事 ，本文 是向大家解釋一種方法 當然如果你知道遙控器的編碼 那么 我想寫解碼程序應該是很簡單的事 而我的意思是說我們現在從0開始 拿到任何一種遙控板 那怕不知道它的型號 但是 大家想 即使它什么型號都沒寫 但是按一下不同的鍵 它的發射的脈沖 肯定不一樣 無非就是引導碼 然后 地址碼 鍵碼 驗證碼 因為不同的遙控板 它所定義的規則不一樣 （這里說一點題外話 其實在讀出波型后 大家就可以看出這個遙控板最開始設計時的人的意思 或者說考慮 它的這個設計方式是否是最好的 是否穩定 是否具有通用性 或者說 日本的和中國的設計師 在設計時他們所考慮的 名牌和 雜牌的 他們在設計時所考慮的 等等 這些其實也是件很有意思的事 就像偷窺到一個人的內心世界一樣 扯遠了 。。--）
  下面我們來說說本問利用51單片機軟件解密的方法 首先大家看了我剛才貼出來的連接 應該知道了 編碼無非就是低電平高電平。但是我們知道一點 它肯定是有規律的 （這里申明一下 如果你能找到它的PDF 上面寫好了它的波形 或者你在網上找到了前人把某型號的遙控器的波形已經分析出來了那么你完全可以把這篇帖子當水貼 跳過 我這里的目的是想通過一種方法 一種 完整的分析方法  就像醫生拿起手術刀 解開它的內部 看常人所不能看到的東西 最終能把一種很通用的東西 把它的內部原理能夠完全的理解 一切從簡單學起 做起 以后凡是涉及到 這種 類型的東西 相信你會更加自信 而不是只滿足做一個課程設計 一個老師布置的作業 扯遠了。。  ）
  具體我們怎么記錄這種規律  很簡單 我們用定時器把每個高低電平的時間記下來 然后顯示在數碼管上 設置2秒顯示一個數據 然后用EXCLE記錄下來
再用鉛筆 或者 隨便什么畫圖軟件 把它的波形畫出來 標上 低電平 高電平 再對比下不同的鍵的區別 一切就豁然開朗了
 現在舉 實際的例子
萬能遙控板大家應該都知道吧

           dec r1
           jb   p3.6,$          ;等待變低 , 即等待按鍵
next:      setb tr1             ;啟動定時器1
           jnb p3.6,$   ;  等待變高，以測量低電平時間寬度
           clr tr1      ;關閉定時器1                             ;1US
           inc r5       ;時間值個數加1                           ;1
           inc r1                                                ;1
           mov @r1,th1  ;存低電平時間值 ，先存高8位，后存低8位   ;2US
           inc r1                                                ;1
           mov @r1,tl1                                           ;2
           mov th1,#0   ;重賦初值                                ;2
           mov tl1,#13  ;13為停止T1到重啟T1經過的時間            ;2
           setb tr1     ;重新啟動定時器                          ;1
           jb p3.6,$    ;等待變低
           clr tr1      ;關閉定時器1                             ;1
           inc r5                                                ;1
           inc r1                                                ;1
           mov @r1,th1  ;存高電平時間值                          ;2
           inc r1                                                ;1
           mov @r1,tl1                                           ;2
           mov th1,#0   ;重賦初值                                ;2
           mov tl1,#15  ;15為停止T1到重啟T1經過的時間            ;2
           ajmp next    ;循環檢測，直到T1在遙控器無鍵按下時溢出時產生中斷   ;2
           ajmp $
;-----------------------------------------
 ;定時器1中斷程序
 ;在遙控器無鍵按下時產生中斷，便依次將BMHCQ中的高低電平時間值轉換為BCD碼并顯示出來
;-----------------------------------------
t1zd:
          setb tr0       ;啟動T0
          clr tr1        ;關閉T1
          setb et0       ;T0開中斷
          mov a,r5
          mov r2,a
          mov r3,#0
          lcall hextoxcq
          lcall display
          jb yszt,$           ;延時一段時間，以便記錄顯示的時間值
          setb yszt
          mov r0,#bmhcq
dispnext: mov a,@r0           ;從BMHCQ中依次取出時間值（16位）調BTOD子程序將其轉換為5位BCD碼并放入XCQ中再調顯示子程序顯示
          mov r3,a  ;取高8位
          inc r0
          mov a,@r0
          mov r2,a   ;取低8位
          inc r0
          ;lcall BtoD      ;將高電平或低電平時間值轉為BCD碼放于XCQ中
          lcall HEXtoXCQ   ;將高電平或低電平時間值轉為十六進制的LED碼放于XCQ中
          lcall display   ;顯示
          cpl p2.5        ;改變批示燈的狀態，以此說明顯示內容的改變
          jb    yszt,$    ;延時，以便抄錄時間值
          setb  yszt
          djnz r5,dispnext ;獲取的時間值沒顯示完則繼續
          sjmp $           ;顯示完畢，在此踏步
          reti
         
 HEXtoXCQ:
          push 00h
          mov r0,#xcq
          mov a,r2
          anl a,#0fH
          mov dptr,#LED
          movc a,@a+dptr
          mov @r0,a
          inc r0
          mov a,r2
          swap a
          anl a,#0fH
          mov dptr,#LED
          movc a,@a+dptr
          mov @r0,a
          inc r0
         
          mov a,r3
          anl a,#0fH
          mov dptr,#LED
          movc a,@a+dptr
          mov @r0,a
          inc r0
          mov a,r3
          swap a
          anl a,#0fH
          mov dptr,#LED
          movc a,@a+dptr
          mov @r0,a
          inc r0
          mov @r0,#7eh
          inc r0
          mov @r0,#7eh
          pop 00H
          ret
 led:    db 7eh,30h,6dh,79h,33h,5bh,5fh,70h,7fh,7bh,77h,1fh,4eh,3dh,4fh,47h                         

;---------------------------------------------
;將存于R3R2中高電平或低電平時間值轉為BCD碼放于XCQ中
;---------------------------------------------
BtoD:
         push 00h
         mov r0,#BCD
         mov r4,#3
bd0:     mov @r0,#0       ;BCD緩沖區清0
         inc r0
         djnz r4,bd0
         mov r6,#16
bd1:     clr c            ;將R3R2中的16位二進制值轉換為三字節BCD碼存入BCD緩沖區中
         mov a,r3
         rlc a
         mov r3,a
         mov a,r2
         rlc a
         mov r2,a
         mov r4,#3
         mov r1,#bcd
BD3:     mov a, @r1
         addc a,@r1
         da a
         mov @r1,a
         inc r1
         djnz r4,bd3
         djnz r6,bd1
         mov r0,#xcq      ;將轉換結果從BCD緩沖中存入XCQ中
         mov r1,#bcd
         mov r4,#3
bd4:     mov a,@r1
         xchd a,@r0
         inc r0
         swap a
         xchd a,@r0
         inc r0
         inc r1
         djnz r4,bd4
         pop 00h
         ret

通過上面的程序我們讀出了按下一個鍵后的編碼的本質的東西
  那么動手把 圖畫下來 找規律 解碼 
我把我例子長虹解碼后的波形圖 發出來

 01。JPG 是脈沖開始時所有鍵前8個完全一樣的高低脈沖

02.jpg (88.76 KB, 下載次數: 204)

下載附件

2009-5-7 17:31 上傳

02。JPG 大家注意看按不同的鍵 中間只是有3個脈沖在變化 是EXCLE的 W列-AC列 而這3位數值就是我們解碼的關鍵 01。JPG 中8位數 大家應該看出 所有鍵都是一樣的11100010 后面02。JPG中我們把鍵碼整理出來就是 
按1鍵 00000000  00H
按2鍵 00010000  10H
按3鍵 00001000  08H
按4鍵 00011000  18H
按5鍵 。。。。。
后面就不寫了
為了大家清晰可見 我把畫出的最后的波形圖03。JPG 貼出來 大家看下規律 

03.jpg (32.53 KB, 下載次數: 201)

下載附件

2009-5-7 17:32 上傳

然后我們 來分析應該怎么解碼 我相信到了這一步應該很簡單了吧 比如在這個例子中 我們發現 后面的鍵碼改變的部分完全是重復

DYKJZ:     JB   P3.6,$

           LCALL YKJM  ；核心解碼代碼子程序
           cpl a
           jz    no     ;判斷是否為錯誤代碼（0FFH)
           cpl a

           AJMP JZPD
NO:      LJMP  DYKJZ
            RET 

JZPD:    CJNE A,#09H,JZ1  ；鍵碼為09H嗎？
            AJMP KAIS            ；鍵碼為09H 轉開始程序（）

JZ1:                                ；不為09H 轉最開始 等待下一次遙控器按鍵到來
            AJMP DYKJZ      
            RET
KAIS： ；放你需要執行的代碼 
           ；比如 點亮一個燈 給單片機接上串口   用單片機控制電腦的打開 放音樂。等等 
           ；這些不屬于本問討論的范圍 有興趣的可以自己擴展
        RET
；-----------------------
  ；核心解碼代碼子程序
；------------------------
YKJM：
       

           PUSH         PSW
           PUSH         02H
           PUSH         06H
           PUSH         07H
           PUSH         B
           MOV          B,#0FFH
           JNB          TF1,JMCW                ;通過T1從0開始定時到溢出來避開遙控器的重發碼 ，也就是說在讀了一個遙控按鍵后
           CLR          TF1                     ;到少要等到T1從0開始定時到溢出才能讀取第二個按鍵

;引導碼正確時執行以下代碼
        ;   CLR          YKBZ                    ;遙控標志清0
JM21:
           MOV          R2,#16                  ;每次循環讀8位碼
           MOV          R6,#0                   ;存放16位碼中的低8位
           MOV          R7,#0                   ;存放16位碼中的高8位
JM3:
           JNB          P3.6,$                  ;等待低電平結束，不管其寬度，因為是通過高電平的寬度來區分0（約為0.5ms）和1（約為1.6ms）
           MOV          TH1,#0
           MOV          TL1,#0
           SETB         TR1                     ;啟動T1，統計高電平的寬度
           JB           P3.6,$
           CLR          TR1
    MOV   A,TH1
           CJNE         A,#2,JM4                ;若高電平寬度值大于2，則說明此高電平為寬脈沖（1），否則為窄脈沖（0）
JM4:       CPL          C                       ;當TH1的值大于2時，C=0，小于2時，C=1
           MOV          A,R7
           RRC          A
           MOV          R7,A
           MOV          A,R6
           RRC          A
           MOV          R6,A
           DJNZ         R2,JM3          ;連讀16位，先讀的為低位，后讀的為高位，高8位(數據碼）存于R7中，低8位（地址碼）存于R6中
           MOV          A,R6
           CJNE         A,#47H,JMCW     ;判斷地址碼是否為47H，不是轉出錯返回
           MOV          A,R7            ;若地址碼正確，則R7中便為數據碼
           mov          r1,#jzh
           mov          @r1,A
           LJMP         JMFH
JMCW:      MOV          A,B
JMFH:      CLR          TF1            ;T1的溢出標志清0
           MOV          TH1,#0          ;為T1設定初值并啟動它
           MOV          TL1,#0          ;以此來避免對同一按鍵讀兩次（避開遙控器的重發代碼）
           SETB         TR2
           POP          B
           POP          07H
           POP          06H
           POP          02H
           POP          PSW
           RET                          ;此時，若引導碼、地址碼、鍵值碼和鍵值反碼中有一個有問題，A中便為錯誤代碼，否則，A中便為所按鍵之鍵值碼

 文章寫完了。希望能對大家有少許的幫助 覺得有用就拿去研究下吧。最后放上完整的EXCLE 數據分析表 和 整理出的波形圖 大家看不清楚的下載后看完整的圖
 “要發只發精品   把最好的給大家”

[ 原 創 ] Suse| haozi
2009.5.7 15:55
www.zg4o1577.cn 轉載請注明出處

呀這個好玩

謝謝版主，看到你這個帖子我非常感謝，我最近在做一個學習萬能型遙控器，我覺得我研究了版主這個主題后，我就能做出來 ，

我想問下版主，請問這里介紹的方法可以解碼任何制式的，是么？

這個是nec的吧

我做了一個解碼器，但不是任何遙控器都能解的，只能自動識別并解出23種編碼

http://bbs.lcdhome.net/read.php?tid=222321&page=1&toread=1

認真學習

1
！！！！！