這個在單片機p1.1接一個了led怎么不閃爍?

ID:661998 · 發表于 2019-12-11 22:18

假定P1.0每秒產生一個機器周期的正脈沖，P1.1每分鐘產生一個機器周期的正脈沖。

單片機是89C51。

ORG 0000H
   AJMP START
   ORG 000BH             ;定時器0中斷入口.
   AJMP SERVE
START:
   MOV TMOD, #01H          ;T0定時方式0
   MOV TH0, #3CH          ;定時
   MOV TL0, #0B0H
   SETB TR0                ;啟動.
   SETB ET0                ;允許中斷.
   SETB EA
   MOV R2, #20          ;秒.
   MOV R3, #60          ;分.
   CLR P1.0                ;開始時，輸出低電平.
   CLR P1.1

   SJMP $                ;等待中斷.
;--------------------------------------------
SERVE:                         ;50ms執行一次本中斷程序.
   MOV TL0, #0B0H          ;重新送入初始值.
   MOV TH0, #3CH          ;定時
   DJNZ R2, T0_END       ;不到20次轉移.
   SETB P1.0                ;到了20次，就是到了1秒，輸出正脈沖.
   CLR P1.0                ;馬上就恢復為0，這就是1個機器周期.
   MOV R2, #20
   DJNZ R3, T0_END       ;不到60秒轉移.
   SETB P1.1                ;到了60秒，輸出正脈沖.
   CLR P1.1                ;馬上就恢復為0，這就是1個機器周期.
   MOV R3, #60
T0_END:
   RETI
;--------------------------------------------
END

ID:235200 · 發表于 2019-12-12 00:24

中斷程序應該改一下,1個機器大約1us左右,無法點亮LED
SERVE:                         ;50ms執行一次本中斷程序.
   MOV TL0, #0B0H          ;重新送入初始值.
   MOV TH0, #3CH          ;定時
   DJNZ R2, T0_END       ;不到20次轉移.
   CPL    P1.0                ;到了20次，1秒鐘翻轉一次
   MOV R2, #20
   DJNZ R3, T0_END       ;不到60秒轉移.
   CPL    P1.1                ;到了60秒，LED亮滅翻轉
   MOV R3, #60
   MOV R2,#20
T0_END:
   RETI

ID:10193 · 發表于 2019-12-12 08:01

輸出高電平時間太短了，微妙級，LED估計都反映不過來，而且人眼也看不到

帳號		自動登錄	找回密碼
密碼			立即注冊

久久久久久久999_99精品久久精品一区二区爱城_成人欧美一区二区三区在线播放_国产精品日本一区二区不卡视频_国产午夜视频_欧美精品在线观看免费

這個在單片機p1.1接一個了led怎么不閃爍?