求一份51單片機(jī)和DS18B20匯編程序

ID:576088 · 發(fā)表于 2020-8-23 11:01

學(xué)習(xí)DS18B20好久了，想用匯編語(yǔ)言。以下是我的代碼，仿真LED用來(lái)檢測(cè)溫度能否正確轉(zhuǎn)換。求大佬可以指正，或者有匯編語(yǔ)言寫(xiě)的ds18b20直接分享我一份謝謝

DQ BIT P1.3
DQ_DELAY EQU 40H ;40H存放延時(shí)所需的時(shí)間
LSB       EQU 29H ;讀取溫度的低字節(jié)
MSB       EQU 28H ;讀取溫度的高字節(jié)
TEMP_XIAO EQU 27H ;保存溫度的小數(shù)部分
TEMP_GE       EQU 26H ;保存溫度的個(gè)位
TEMP_SHI EQU 25H ;保存溫度的十位
TEMP_BAI EQU 24H ;保存溫度的百位
TEMP_FU       EQU 23H ;保存溫度的正負(fù)號(hào)
ORG 0000H
LJMP START
ORG 001BH       ;T1中斷入口地址
LJMP INT_T1
ORG 0100H
START: MOV SP,#60H
;MOV R1,#28H
LCALL INTI_T1       ;設(shè)置T1相關(guān)的寄存器

LOOP:
CJNE R2,#1,NEXT
;R2=1,2s定時(shí)，開(kāi)始進(jìn)行溫度轉(zhuǎn)換
LCALL STRAT_18B20 ;啟動(dòng)一次18B20
LCALL TEMP_PROC ;轉(zhuǎn)換得到溫度的各位

MOV A,25H          ;選轉(zhuǎn)換后的十位簡(jiǎn)單檢測(cè)是否能轉(zhuǎn)換成功
CPL A
MOV P0,A
NEXT: LJMP LOOP

;轉(zhuǎn)換得到溫度的各位
TEMP_PROC:
MOV A,MSB
MOV TEMP_FU,#'+'
RLC A
JNC TEMP_VALUE
MOV TEMP_FU,#'-'
MOV A,LSB       ;若為負(fù)值，取反加一
CPL A
INC A
MOV LSB,A
MOV A,MSB
CPL A
MOV MSB,A

TEMP_VALUE:
MOV A,LSB
ANL A,#0FH       ;小數(shù)部分，低字節(jié)低四位
MOV B,#10       ;小數(shù)部分處理，乘以10，再除以16即為小數(shù)值
MUL AB
MOV B,#16
DIV AB
MOV TEMP_XIAO,A ;存儲(chǔ)小數(shù)值

MOV A,LSB
SWAP A       ;交換指令，整數(shù)部分在低位
ANL A,#0FH       ;屏蔽高四位得到低4位的整數(shù)部分
MOV R0,A       ;暫存低四位
MOV A,MSB       ;取高字節(jié)的整數(shù)部分
SWAP A
ORL A,R0       ;與低位相或，得到實(shí)際溫度的整數(shù)部分
MOV B,#100
DIV AB
MOV TEMP_BAI,A ;存儲(chǔ)百位
MOV A,B       ;十位個(gè)位數(shù)據(jù)
MOV B,#10
DIV AB
MOV TEMP_SHI,A
MOV TEMP_GE,B
RET

;啟動(dòng)一次18B20
STRAT_18B20:
;復(fù)位總線(xiàn)，獲取存在脈沖，以啟動(dòng)一次讀寫(xiě)操作
CLR EA       ;禁止中斷
CLR DQ       ;產(chǎn)生500us復(fù)位脈沖
MOV DQ_DELAY,#50
LCALL DELAY_US
SETB DQ
MOV DQ_DELAY,#6 ;延時(shí)60us
LCALL DELAY_US
WAIT1:
JB DQ,WAIT1 ;DQ=0時(shí)，表示讀取到了低電平
SETB EA       ;使能總中斷
;DQ=0，18B20正確應(yīng)答，讀取溫度值
MOV A,#0CCH       ;跳過(guò)ROM
LCALL WR_18B20
MOV A,#44H       ;啟動(dòng)一次溫度轉(zhuǎn)換
LCALL WR_18B20
MOV A,#0BEH       ;發(fā)送讀命令
LCALL WR_18B20
LCALL READ_18B20 ;讀低八位
MOV LSB,A
LCALL READ_18B20 ;讀高八位
MOV MSB,A
RET

;向18B20寫(xiě)一字節(jié)，內(nèi)容存在A
WR_18B20:
CLR EA
MOV R3,#8       ;一個(gè)字節(jié)8bit
CLR C
LOOP2:
RRC A
CLR DQ
NOP          ;延時(shí)2us
NOP
MOV DQ,C
MOV DQ_DELAY,#6 ;延時(shí)60us
LCALL DELAY_US
SETB DQ       ;拉高通信引腳
NOP
DJNZ R3,LOOP2
SETB EA
RET

;讀取DS18B20一個(gè)字節(jié)，存在A中
READ_18B20:
CLR EA
MOV R4,#8

LOOP3:
CLR DQ
NOP          ;延時(shí)2us
NOP
SETB DQ
NOP
NOP
MOV C,DQ       ;讀取通信引腳，賦值給Cy
RRC A
MOV DQ_DELAY,#6 ;延時(shí)60us
LCALL DELAY_US
DJNZ R4,LOOP3
SETB EA
RET

;初始化T1設(shè)置相關(guān)寄存器
INTI_T1:
MOV TMOD,#11H ;設(shè)置T1為方式1
MOV TL1,#0FCH ;設(shè)定時(shí)為50ms
MOV TH1,#4BH
MOV R1,#28H       ;輔助定時(shí)器1定時(shí)2s
SETB TR1       ;啟動(dòng)T1
SETB ET1       ;開(kāi)T1中斷
SETB EA       ;開(kāi)總中斷
RET

;T1中斷服務(wù)子程序，定時(shí)2s
INT_T1:
PUSH PSW       ;保護(hù)現(xiàn)場(chǎng)
MOV TL1,#0FCH ;設(shè)定時(shí)為50ms，重新裝載
MOV TH1,#4BH
DJNZ R1,RETURN

MOV R1,#28H       ;延時(shí)2s的常數(shù)
MOV R2,#1       ;定時(shí)2s，開(kāi)啟新一次溫度轉(zhuǎn)換
RETURN: POP PSW
RETI

;延時(shí)us的子程序，延時(shí)時(shí)間存在DQ_DELAY
DELAY_US:
MOV R6,DQ_DELAY
DELAY:
MOV R7,#3
DJNZ R7,$
DJNZ R6,DELAY
RET

END

ID:235200 · 發(fā)表于 2020-8-24 13:05

晶振：12M
TEMPER_L EQU 36H
TEMPER_H EQU 35H
TEMPER_NUM  EQU 60H
FLAG1    BIT 00H
DQ       BIT P0.0

AAA:MOV SP,#70H
   LCALL GET_TEMPER
   LCALL TEMPER_COV
   LJMP  AAA
   NOP
   ;------------------讀出轉(zhuǎn)換后的溫度值
GET_TEMPER:
   SETB  DQ          ; 定時(shí)入口
BCD:LCALL INIT_1820
   JB FLAG1,S22
   LJMP  BCD       ; 若DS18B20不存在則返回

S22:LCALL DELAY1
   MOV A,#0CCH       ; 跳過(guò)ROM匹配------0CC
   LCALL WRITE_1820
   MOV A,#44H       ; 發(fā)出溫度轉(zhuǎn)換命令
   LCALL WRITE_1820
   NOP
   LCALL DELAY
   LCALL DELAY
CBA:LCALL INIT_1820
   JB FLAG1,ABC
   LJMP  CBA
ABC:LCALL DELAY1
   MOV A,#0CCH       ; 跳過(guò)ROM匹配
   LCALL WRITE_1820
   MOV A,#0BEH       ; 發(fā)出讀溫度命令
   LCALL WRITE_1820
   LCALL READ_18200 ;READ_1820
   RET
      ;------------------讀DS18B20的程序,從DS18B20中讀出一個(gè)字節(jié)的數(shù)據(jù)
READ_1820:
   MOV R2,#8
RE1:
   CLR C
   SETB DQ
   NOP
   NOP
   CLR DQ
   NOP
   NOP
   NOP
   SETB DQ
   MOV R3,#7
   DJNZ R3,$
   MOV C,DQ
   MOV R3,#23
   DJNZ R3,$
   RRC A
   DJNZ R2,RE1
   RET

   ;-------------------寫(xiě)DS18B20的程序
WRITE_1820:
   MOV R2,#8
   CLR C
WR1:
   CLR DQ
   MOV R3,#6
   DJNZ R3,$
   RRC A
   MOV DQ,C
   MOV R3,#23
   DJNZ R3,$
   SETB DQ
   NOP
   DJNZ R2,WR1
   SETB DQ
   RET
   ;-------------------讀DS18B20的程序,從DS18B20中讀出兩個(gè)字節(jié)的溫度數(shù)據(jù)
READ_18200:
   MOV R4,#2          ; 將溫度高位和低位從DS18B20中讀出
   MOV R1,#36H       ; 低位存入36H(TEMPER_L),高位存入35H(TEMPER_H)
RE00:
   MOV R2,#8
RE01:
   CLR C
   SETB DQ
   NOP
   NOP
   CLR DQ
   NOP
   NOP
   NOP
   SETB DQ
   MOV R3,#7
   DJNZ R3,$
   MOV C,DQ
   MOV R3,#23
   DJNZ R3,$
   RRC A
   DJNZ R2,RE01
   MOV @R1,A
   DEC R1
   DJNZ R4,RE00
   RET

   ;-------------------將從DS18B20中讀出的溫度數(shù)據(jù)進(jìn)行轉(zhuǎn)換
TEMPER_COV:
   MOV A,#0F0H
   ANL A,TEMPER_L       ; 舍去溫度低位中小數(shù)點(diǎn)后的四位溫度數(shù)值
   SWAP A
   MOV TEMPER_NUM,A
   MOV A,TEMPER_L
   JNB ACC.3,TEMPER_COV1 ; 四舍五入去溫度值
   INC TEMPER_NUM

TEMPER_COV1:
   MOV A,TEMPER_H
   ANL A,#07H
   SWAP A
   ORL A,TEMPER_NUM
   MOV TEMPER_NUM,A ; 保存變換后的溫度數(shù)據(jù)
   LCALL BIN_BCD
   RET
   ;-------------------將16進(jìn)制的溫度數(shù)據(jù)轉(zhuǎn)換成壓縮BCD碼
BIN_BCD:
   MOV DPTR,#TEMP_TAB
   MOV A,TEMPER_NUM
   MOVC A,@A+DPTR
   MOV TEMPER_NUM,A
   RET

TEMP_TAB:
   DB 00H,01H,02H,03H,04H,05H,06H,07H
   DB 08H,09H,10H,11H,12H,13H,14H,15H
   DB 16H,17H,18H,19H,20H,21H,22H,23H
   DB 24H,25H,26H,27H,28H,29H,30H,31H
   DB 32H,33H,34H,35H,36H,37H,38H,39H
   DB 40H,41H,42H,43H,44H,45H,46H,47H
   DB 48H,49H,50H,51H,52H,53H,54H,55H
   DB 56H,57H,58H,59H,60H,61H,62H,63H
   DB 64H,65H,66H,67H,68H,69H,70H,71H
   DB 72H,73H,74H,75H,76H,77H,78H,79H
   DB 80H,81H,82H,83H,84H,85H,86H,87H
   DB 88H,89H,90H,91H,92H,93H,94H,95H
   DB 96H,97H,98H,99H

   ;-------------------DS18B20初始化程序
INIT_1820:
      SETB DQ
      NOP
      CLR DQ
      MOV R0,#80H
TSR1:
      DJNZ R0,TSR1       ; 延時(shí)
      SETB DQ
      MOV R0,#25H       ;96US-25H
TSR2:
      DJNZ R0,TSR2
      JNB DQ,TSR3
      LJMP TSR4          ; 延時(shí)
TSR3:
      SETB FLAG1 ; 置標(biāo)志位,表示DS1820存在
      LJMP TSR5
TSR4:
      CLR FLAG1    ; 清標(biāo)志位,表示DS1820不存在
      LJMP TSR7
TSR5:
      MOV R0,#06BH       ;200US
TSR6:
      DJNZ R0,TSR6       ; 延時(shí)
TSR7:
      SETB DQ
      RET
      ;------------------重新寫(xiě)DS18B20暫存存儲(chǔ)器設(shè)定值
RE_CONFIG:
      JB FLAG1,RE_CONFIG1 ; 若DS18B20存在,轉(zhuǎn)RE_CONFIG1
      RET
RE_CONFIG1:
      MOV A,#0CCH       ; 發(fā)SKIP ROM命令
      LCALL WRITE_1820
      MOV A,#4EH       ; 發(fā)寫(xiě)暫存存儲(chǔ)器命令
      LCALL WRITE_1820

      MOV A,#00H       ; TH(報(bào)警上限)中寫(xiě)入00H
      LCALL WRITE_1820
      MOV A,#00H       ; TL(報(bào)警下限)中寫(xiě)入00H
      LCALL WRITE_1820
      MOV A,#7FH       ; 選擇12位溫度分辨率
      LCALL WRITE_1820
      RET
      ;------------------延時(shí)子程序
  DELAY:MOV R7,#00H
MIN:DJNZ  R7,YS500
      RET
  YS500:LCALL YS500US
      LJMP  MIN
YS500US:MOV R6,#00H
      DJNZ  R6,$
      RET
DELAY1:MOV R7,#20H
      DJNZ  R7,$
      RET

帳號(hào)		自動(dòng)登錄	找回密碼
密碼			立即注冊(cè)

久久久久久久999_99精品久久精品一区二区爱城_成人欧美一区二区三区在线播放_国产精品日本一区二区不卡视频_国产午夜视频_欧美精品在线观看免费

求一份51單片機(jī)和DS18B20匯編程序