|
|
; ledpwm.asm --- drive a blue LED with PWM 21/04/2006
; Copyright (c) 2006 John Honniball
.include "m8def.inc"
.org 0x0000
; 端口 B 位 2 上的LED
.equ LED_PORT = PortB
.equ LED_BIT = 2
; 該程序驅(qū)動(dòng)連接到 AVR 的 I/O 端口的單個(gè) LED。 它將 LED 的陰極連接到 AVR 引腳，
;LED 的陽(yáng)極通過(guò)電阻器。 該電阻的值取決于 LED 的顏色，但通常為幾百歐姆。
;我們通過(guò)脈寬調(diào)制 （PWM） 控制 LED 的亮度，
; 就像脈動(dòng)那樣地周期運(yùn)動(dòng)或變化 從未完全“熄滅昏暗狀態(tài)”到全亮度再調(diào)至昏暗狀態(tài)，然后再變回來(lái)。
;為此，設(shè)置最小亮度、最大亮度值。
.equ MIN_BRIGHT = 15 ;最小亮度
.equ MAX_BRIGHT = 255 ;最大亮度
; 此值控制 LED 從亮到暗的循環(huán)速度。 是的我們?yōu)榱炼鹊拿恳徊缴傻腜WM周期數(shù)
;坡道，上坡和坡道。 數(shù)字越大，脈動(dòng)越慢。
.equ N_CYCLES = 6 ;周期數(shù)
; 重置后開始執(zhí)行程序
ldi r16,low(RAMEND) ; 初始化堆棧到RAM頂部
out SPL,r16
ldi r16,high(RAMEND)
out SPH,r16
; 初始化硬件
ldi r16,0xff ; 將端口B設(shè)置為所有輸出
out DDRB,r16
sbi LED_PORT,LED_BIT ;通過(guò)將輸出引腳設(shè)置為高電平關(guān)閉藍(lán)色LED
; 從LED處于最低水平開始，然后上升到最大水平
dopwm: ldi r17,MIN_BRIGHT ; R17保持當(dāng)前亮度水平
adjust_1: ldi r18,N_CYCLES ; R18計(jì)算PWM周期，從而計(jì)算脈動(dòng)速度
adjust_2: cbi LED_PORT,LED_BIT ; 輸出引腳低，LED亮起
mov r16,r17 ;R16控制延遲長(zhǎng)度（=R17）
rcall delayn4us ;調(diào)用延遲子程序
sbi LED_PORT,LED_BIT ; 輸出引腳高，LED熄滅
ldi r16,255
sub r16,r17 ; R16控制延遲長(zhǎng)度（=255-R17）
rcall delayn4us ; 調(diào)用延遲子程序
dec r18 ;遞減PWM周期計(jì)數(shù)器
brne adjust_2
inc r17 ; 亮度增加一步
brne adjust_1
; 現(xiàn)在逐漸降低到最小亮度
ldi r17,MAX_BRIGHT ;R17 保持當(dāng)前亮度水平
adjust_3: ldi r18,N_CYCLES ;R18 計(jì)算 PWM 周期，從而計(jì)算脈動(dòng)速度
adjust_4: cbi LED_PORT,LED_BIT ;輸出引腳低電平，LED 亮起
MOV R16,R17 ;R16 控制延遲長(zhǎng)度 （= R17）
rcall delayn4us ;呼叫延遲子例程
sbi LED_PORT,LED_BIT ;輸出引腳高電平，LED 熄滅
ldi R16,255
sub R16,R17 ;R16 控制延遲長(zhǎng)度 （= 255 - R17）
rcall delayn4us ;呼叫延遲子例程
dec R18 ;遞減PWM周期計(jì)數(shù)器
brne adjust_4
dec R17 ;亮度降低一級(jí)
CPI r17,MIN_BRIGHT ;我們達(dá)到最低限度了嗎？
brne adjust_3
rjmp dopwm ; 循環(huán)回到開始
; delayn 4US
;延遲 （R16 * 4） 微秒
delayn4us: tst r16 ; R16 = 0？（無(wú)延遲）
breq dly4
dly2: ldi r24,low(16)
ldi r25,high(16)
dly3: sbiw r24,1 ; 2 個(gè)周期
brne dly3 ; 2 個(gè)周期
dec r16
brne dly2
dly4: ret ;返回
|
|
